[gentoo-commits] repo/gentoo:master commit in: app-crypt/swtpm/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     5305e1730a21e514e34967545ea61f11ed984f91
Author:     Christopher Byrne <salah.coronya <AT> gmail <DOT> com>
AuthorDate: Tue Sep 21 19:34:40 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Sep 24 07:21:54 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5305e173

app-crypt/swtpm: Bump to 0.6.1

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Christopher Byrne <salah.coronya <AT> gmail.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 app-crypt/swtpm/Manifest           |  1 +
 app-crypt/swtpm/swtpm-0.6.1.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/app-crypt/swtpm/Manifest b/app-crypt/swtpm/Manifest
index bdcdcc6c203..64edf0449a2 100644
--- a/app-crypt/swtpm/Manifest
+++ b/app-crypt/swtpm/Manifest
@@ -1 +1,2 @@
 DIST swtpm-0.6.0.tar.gz 326049 BLAKE2B 52b310e4da1f256f440d9e0022cb6d5f5987b10aa85c8bf2837f5a5c61bc076f7d24d0a027987ef28ba0e7983a2fb04476103b88c33e3312536777366bf9b0cd SHA512 b12bb9cc486c50d0689a5655799c0d52f85d320a1d849fd56ee5c4b497472102c61b5d368f46a81e0b9feacc63b25b434bd6229f492951097af1e9c74a37cc96
+DIST swtpm-0.6.1.tar.gz 326488 BLAKE2B 46c53cbd4195cfc1d45ef5e56b1f78c59dcb9f859349e161f07d9933ce720ec3511343cf29236119d08162410355fc50cb5d15745c84db78d860b006812c169f SHA512 a44e36820ad61e84d62b330f3adf0c463c98438056d74c5ba30916d956e722633e0198ae87be8352a0ab909ae5a4bbc3826410d2166186c43bba067f533fec85

diff --git a/app-crypt/swtpm/swtpm-0.6.1.ebuild b/app-crypt/swtpm/swtpm-0.6.1.ebuild
new file mode 100644
index 00000000000..ef5db8666fa
--- /dev/null
+++ b/app-crypt/swtpm/swtpm-0.6.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Libtpms-based TPM emulator"
+HOMEPAGE="https://github.com/stefanberger/swtpm"
+SRC_URI="https://github.com/stefanberger/swtpm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="fuse +gnutls seccomp test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="fuse? (
+		dev-libs/glib:2
+		sys-fs/fuse:0
+	)
+	gnutls? (
+		dev-libs/libtasn1:=
+		>=net-libs/gnutls-3.1.0[tools,pkcs11]
+	)
+	seccomp? ( sys-libs/libseccomp )
+	acct-group/tss
+	acct-user/tss
+	dev-libs/openssl:0=
+	dev-libs/json-glib
+	dev-libs/libtpms
+	${PYTHON_DEPS}"
+
+DEPEND="${RDEPEND}
+	test? (
+		net-misc/socat
+		dev-tcltk/expect
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.6.0-fix-localca-path.patch"
+	"${FILESDIR}/${PN}-0.5.0-build-sys-Remove-WError.patch"
+)
+
+src_prepare() {
+	use test || eapply "${FILESDIR}/${PN}-0.5.0-disable-test-dependencies.patch"
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-openssl \
+		--without-selinux \
+		$(use_with fuse cuse) \
+		$(use_with gnutls) \
+		$(use_with seccomp)
+}
+
+src_install() {
+	default
+	fowners -R tss:root /var/lib/swtpm-localca
+	fperms 750 /var/lib/swtpm-localca
+	keepdir /var/lib/swtpm-localca
+	find "${D}" -name '*.la' -delete || die
+}