[gentoo-commits] repo/gentoo:master commit in: media-sound/sox/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     a01c742fa152cbfaa8dc95eea382d9b1ece29385
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 22 04:09:57 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Sep 22 04:09:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a01c742f

media-sound/sox: bump to 14.4.2_p20210509

updated ./configure options according to the upstream changes,
dropped debug use flag

Bug: https://bugs.gentoo.org/813783
Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/sox/Manifest                    |   1 +
 media-sound/sox/sox-14.4.2_p20210509.ebuild | 108 ++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/media-sound/sox/Manifest b/media-sound/sox/Manifest
index f8cd840cafa..a1b59d86eef 100644
--- a/media-sound/sox/Manifest
+++ b/media-sound/sox/Manifest
@@ -1 +1,2 @@
 DIST sox-14.4.2_p20200803.zip 1089835 BLAKE2B fa53d8c9f14620675bf534090bf6c69ec256bb977aa1b3c01b2d95ba8e685eb4f9d479872f303b2954aa1b063c095bf3b90e5b746fd8d7d66e35476e5218fa6b SHA512 8c485a53b9ecce9ecf759d7bbf8d95e568a89505bec7d1258afded4c7ad0f28c624b637a188ab87b64dee720db59b8de20c347805910f0401f00550832e16392
+DIST sox-14.4.2_p20210509.zip 942551 BLAKE2B 2ddd229faacb9190fe18052b1c02da40d4c3f24fc73dd08b28ac99bef267cb05f8bcbf64e0c397c391b3be2467667783ed94f6c60798af069567e1c237ec9ccd SHA512 4868f9b77141b7e2caf2571ceb68a48bd744732e72f63ed787f8e0b9fe39b77de4e998b32d99c2500e10b017a1fd1a3379f4f9f8b67db6093b85d02cb3447934

diff --git a/media-sound/sox/sox-14.4.2_p20210509.ebuild b/media-sound/sox/sox-14.4.2_p20210509.ebuild
new file mode 100644
index 00000000000..78d457847df
--- /dev/null
+++ b/media-sound/sox/sox-14.4.2_p20210509.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+# We take a snapshot because of the huge number of security
+# and other fixes since the release of 14.4.2.
+# Recommend mirroring the snapshot; unclear if they are stable URIs.
+COMMIT="42b3557e13e0fe01a83465b672d89faddbe65f49"
+MY_P="sox-code-${COMMIT}"
+
+DESCRIPTION="The swiss army knife of sound processing programs"
+HOMEPAGE="http://sox.sourceforge.net"
+# Source: https://sourceforge.net/code-snapshots/git/s/so/sox/code.git/${MY_P}.zip
+SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/${MY_P}.zip -> ${P}.zip"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="alsa amr ao encode flac id3tag ladspa mad ogg openmp oss opus png pulseaudio sndfile sndio static-libs twolame wavpack"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-libs/libltdl:0=
+	>=media-sound/gsm-1.0.12-r1
+	sys-apps/file
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ao? ( media-libs/libao:= )
+	encode? ( >=media-sound/lame-3.98.4 )
+	flac? ( >=media-libs/flac-1.1.3 )
+	id3tag? ( media-libs/libid3tag:= )
+	ladspa? ( media-libs/ladspa-sdk )
+	mad? ( media-libs/libmad )
+	ogg? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	opus? (
+		media-libs/opus
+		media-libs/opusfile
+	)
+	png? (
+		media-libs/libpng:0=
+		sys-libs/zlib
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( >=media-libs/libsndfile-1.0.11 )
+	sndio? ( media-sound/sndio:= )
+	twolame? ( media-sound/twolame )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS )
+
+src_prepare() {
+	default
+
+	# bug #386027
+	sed -i -e 's:CFLAGS="-g":CFLAGS="$CFLAGS -g":' configure.ac || die
+
+	# bug #712630
+	if use elibc_musl ; then
+		ewarn "Applying musl workaround for bug #712630."
+		ewarn "File-type detection with pipes may be missing."
+		sed -i '/error FIX NEEDED HERE/d' src/formats.c || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable alsa) \
+		$(use_enable amr amrnb) \
+		$(use_enable amr amrwb) \
+		$(use_enable ao) \
+		$(use_with encode lame) \
+		$(use_enable flac) \
+		$(use_with id3tag) \
+		$(use_with ladspa) \
+		$(use_with mad) \
+		$(use_enable openmp) \
+		$(use_enable ogg oggvorbis) \
+		$(use_enable oss) \
+		$(use_enable opus) \
+		$(use_with png) \
+		$(use_enable pulseaudio) \
+		$(use_enable sndfile) \
+		$(use_enable sndio) \
+		$(use_enable static-libs static) \
+		$(use_with twolame) \
+		$(use_enable wavpack) \
+		--with-distro="Gentoo"
+}
+
+src_install() {
+	default
+	# libltdl is used for loading plugins, keeping libtool files with empty
+	# dependency_libs what otherwise would be -exec rm -f {} +
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}