[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-vault/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     1cdf98c37420a32258703c942531036479516dde
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 21 18:05:54 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Sep 21 18:26:00 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=1cdf98c3

kde-plasma/plasma-vault: 5.22.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../plasma-vault/plasma-vault-5.22.90.ebuild       | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/kde-plasma/plasma-vault/plasma-vault-5.22.90.ebuild b/kde-plasma/plasma-vault/plasma-vault-5.22.90.ebuild
new file mode 100644
index 0000000000..820c8cb2cc
--- /dev/null
+++ b/kde-plasma/plasma-vault/plasma-vault-5.22.90.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.86.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Plasma applet and services for creating encrypted vaults"
+HOMEPAGE+=" https://cukic.co/2017/02/03/vaults-encryption-in-plasma/"
+
+LICENSE="LGPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="networkmanager"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	|| ( >=sys-fs/cryfs-0.9.9 >=sys-fs/encfs-1.9.2 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package networkmanager KF5NetworkManagerQt)
+	)
+
+	ecm_src_configure
+}