From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1323084-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 57920158012
	for <garchives@archives.gentoo.org>; Tue, 21 Sep 2021 17:13:26 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id A9217E077C;
	Tue, 21 Sep 2021 17:13:25 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-CHACHA20-POLY1305 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 77F59E077C
	for <gentoo-commits@lists.gentoo.org>; Tue, 21 Sep 2021 17:13:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-CHACHA20-POLY1305 (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 4AC58342D56
	for <gentoo-commits@lists.gentoo.org>; Tue, 21 Sep 2021 17:13:24 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id BCE779B
	for <gentoo-commits@lists.gentoo.org>; Tue, 21 Sep 2021 17:13:22 +0000 (UTC)
From: "William Hubbs" <williamh@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "William Hubbs" <williamh@gentoo.org>
Message-ID: <1632244286.2ab3066fcc39c1e775a993b24ffb12694840dde5.williamh@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-apps/openrc/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sys-apps/openrc/Manifest sys-apps/openrc/openrc-0.44.5.ebuild
X-VCS-Directories: sys-apps/openrc/
X-VCS-Committer: williamh
X-VCS-Committer-Name: William Hubbs
X-VCS-Revision: 2ab3066fcc39c1e775a993b24ffb12694840dde5
X-VCS-Branch: master
Date: Tue, 21 Sep 2021 17:13:22 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 3d2a67f2-08ab-4e0a-b9cd-6081580f024a
X-Archives-Hash: 987416df70884e69bb1a814870005f13

commit:     2ab3066fcc39c1e775a993b24ffb12694840dde5
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 21 17:11:07 2021 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Tue Sep 21 17:11:26 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2ab3066f

sys-apps/openrc: 0.44.5 bump

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 sys-apps/openrc/Manifest             |   1 +
 sys-apps/openrc/openrc-0.44.5.ebuild | 168 +++++++++++++++++++++++++++++++++++
 2 files changed, 169 insertions(+)

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 2135982df09..65e7c054e34 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -1,2 +1,3 @@
 DIST openrc-0.43.5.tar.gz 242146 BLAKE2B 993d3895588e8f1383049006834f944faaae0f889d3afcae5bff697db9f26383712f18aba52ce07d835f1d2bbe8ef19ef116ad60141d1eb0650767430d1d9967 SHA512 680c1549a8a37eb3a719f3e026888d045d26c98357d6e6eaf09069a23a001272deaca8cac4a9b8fd79f489c4cfb4fe2c7b5d481d1469798a8f5ec470d0cadbe3
 DIST openrc-0.44.4.tar.gz 253612 BLAKE2B 9c9fb5a6e5124c16bb6b487ae7538a0366c0c66e799a42938be0d5199cd0f9bfa5578d6a2e45c570365bbe900aa5998d748741637325ca540dc788cb9bee5647 SHA512 c900a8e5f91f4261153c67b87ba1fcc8c039b20f23942a12cb0717963060a111bd70eb64418b1c3196ee9ee95db9bb39a1833a84a2c49c1095489d0d472bab74
+DIST openrc-0.44.5.tar.gz 253815 BLAKE2B e0d1ed26a18f59a226a44b3cf041c9b8017fbbe304aa5986d8e5ada17530594ac1a8099bf392ee6cd41c6668ce69a51ee1776817745b568e182bfbeac3a01799 SHA512 95b9399168522ead967a9f1de8ddce3826de997ff0e1acd56b342dc41cf18ea527598ea316e0e377916582a4f6a109a12233bd302e72ae93b3f1bcb81bfe7a4a

diff --git a/sys-apps/openrc/openrc-0.44.5.ebuild b/sys-apps/openrc/openrc-0.44.5.ebuild
new file mode 100644
index 00000000000..c369f95a562
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.44.5.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic meson pam toolchain-funcs
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} =~ ^9{4,}$ ]]; then
+	EGIT_REPO_URI="https://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/OpenRC/openrc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit bash debug ncurses pam newnet +netifrc selinux sysv-utils unicode"
+
+COMMON_DEPEND="
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? ( sys-libs/pam )
+	audit? ( sys-process/audit )
+	sys-process/psmisc
+	!<sys-process/procps-3.3.9-r2
+	selinux? (
+		sys-apps/policycoreutils
+		>=sys-libs/libselinux-2.6
+	)
+	!<sys-apps/baselayout-2.1-r1
+	!<sys-fs/udev-init-scripts-27"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	bash? ( app-shells/bash )
+	!prefix? (
+		sysv-utils? (
+			!sys-apps/systemd[sysv-utils(-)]
+			!sys-apps/sysvinit
+		)
+		!sysv-utils? ( >=sys-apps/sysvinit-2.86-r6[selinux?] )
+		virtual/tmpfiles
+	)
+	selinux? (
+		>=sec-policy/selinux-base-policy-2.20170204-r4
+		>=sec-policy/selinux-openrc-2.20170204-r4
+	)
+	!<app-shells/gentoo-bashcomp-20180302
+	!<app-shells/gentoo-zsh-completions-20180228
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-build.patch"
+)
+
+src_configure() {
+	local emesonargs=(
+	$(meson_feature audit)
+	"-Dbranding=\"Gentoo Linux\""
+		$(meson_use newnet)
+		-Dos=Linux
+		$(meson_use pam)
+		$(meson_feature selinux)
+		-Dshell=$(usex bash /bin/bash /bin/sh)
+		$(meson_use sysv-utils sysvinit)
+		-Dtermcap=$(usev ncurses)
+	)
+	# export DEBUG=$(usev debug)
+	meson_src_configure
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	meson_install
+
+	keepdir /lib/rc/tmp
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/etc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	if use pam; then
+		# install gentoo pam.d files
+		newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+		newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+	fi
+
+	# install documentation
+	dodoc ChangeLog *.md
+}
+
+pkg_preinst() {
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"/etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"/etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+	return 0
+}
+
+pkg_postinst() {
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	# Added for 0.35.
+	if [[ ! -h "${EROOT}"/lib ]]; then
+		if [[ -d "${EROOT}/$(get_libdir)"/rc ]]; then
+			cp -RPp "${EROOT}/$(get_libdir)/rc" "${EROOT}"/lib
+		fi
+	fi
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/connman,"
+		ewarn " net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"/etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+}