[gentoo-commits] repo/gentoo:master commit in: dev-python/nltk/

["Michał Górny" <mgorny@gentoo.org>]

commit:     23453bd55076b23a0aa205aded7d81e8ceb91148
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 20 07:12:37 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Sep 20 13:39:35 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23453bd5

dev-python/nltk: Bump to 3.6.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nltk/Manifest          |  1 +
 dev-python/nltk/nltk-3.6.3.ebuild | 61 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/nltk/Manifest b/dev-python/nltk/Manifest
index 5ec770ae13e..41336034648 100644
--- a/dev-python/nltk/Manifest
+++ b/dev-python/nltk/Manifest
@@ -1 +1,2 @@
 DIST nltk-3.6.2.tar.gz 2819833 BLAKE2B 9796822c35c524432e9790d0890b4388fbaa85b659e5415037422a22e8edbaf20775196b4416f441d62592b387066de9f7741b988c0d463349fc5c906bfd75b2 SHA512 3fd2cba52377613f35f6574f859482de987f969cfc8d4243a859be365ab1bd8300f9013dcedc6caeff7aa7fc035b331a47b557027209ca9a85b0cc7fbde44d6d
+DIST nltk-3.6.3.tar.gz 2824924 BLAKE2B fcab6647f43f4bf139857e9f4202aee688f564851976ed6a183e47361451fae771318346724e41f198b82cebdd5a47f151aaf932099143ef6faa2a77430fbfb4 SHA512 fe7244967df018670501304d1a8aa50a0f4d42bb0c73cc5e202eeab6a0f5da1eaed9b961f6026e3b8ae4b0393d788bcb58b263ba22a3ce6f5644022736035f98

diff --git a/dev-python/nltk/nltk-3.6.3.ebuild b/dev-python/nltk/nltk-3.6.3.ebuild
new file mode 100644
index 00000000000..d3f3e09ad50
--- /dev/null
+++ b/dev-python/nltk/nltk-3.6.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite,tk?,xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Natural Language Toolkit"
+HOMEPAGE="https://www.nltk.org/ https://github.com/nltk/nltk/"
+SRC_URI="https://github.com/nltk/nltk/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="tk"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+		>=dev-python/nltk-data-20200312-r1
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twython[${PYTHON_USEDEP}]
+		sci-libs/scikit-learn[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)"
+PDEPEND="dev-python/nltk-data"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${P}-metadata.patch
+)
+
+src_prepare() {
+	# requires unpackaged pycrfsuite
+	sed -i -e '/>>>/s@$@ # doctest: +SKIP@' nltk/tag/crf.py || die
+	# replace fetching from network with duplicate file URL
+	sed -e 's@https://raw.githubusercontent.com/nltk/nltk/develop/nltk/test/toy.cfg@nltk:grammars/sample_grammars/toy.cfg@' \
+		-i nltk/test/data.doctest || die
+	# requires X and hangs in Xvfb
+	sed -e 's:test_plot:_&:' \
+		-i nltk/test/unit/test_cfd_mutation.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	cd nltk/test || die
+	distutils-r1_src_test
+}