[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     55e1fc87037fba819d10c2f28083104f4de4d170
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 19 09:03:41 2021 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Sep 19 09:35:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=55e1fc87

net-misc/gnome-remote-desktop: Bump to 40.2

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-40.2.ebuild               | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index ebcd7eebd17..e484471b0dc 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-40.1.tar.xz 63980 BLAKE2B 6f5ebe7f00e2038f88740a994ee90f55b7f3ce6e4ea8898b7326d2f36dea2d89c721cffd253f92cde388b1273ad8d086242bfadaa86e4b87361844b3a3bca5b7 SHA512 39116afa16256820a69e020b71de5458fc5da8154bc8255d2157ff56fc679c39f4608f790d74eb4a0cb10cc61bd27d4172cfc547582100cab5b897644a700ee3
+DIST gnome-remote-desktop-40.2.tar.xz 65400 BLAKE2B 47be88529c365e5ab72b225aae1ad0fdca4748c39476ea1251db8f317e7fc25e90acf0b908f64f0a2111e0c59d8a213ede6945fe75151cdca6ab2cf8a77351cc SHA512 f39feb5b4b89d1c504a07c5dcf5962a4340cfc45c70d806a2b6739512ca80671dd8b7928a6dad83165dbba50b17c7961e329ecae0dd59f3f57f4fcf0f7969466

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-40.2.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-40.2.ebuild
new file mode 100644
index 00000000000..8df01c6524e
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-40.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
+inherit gnome.org gnome2-utils meson python-any-r1 systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+rdp +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	>=dev-libs/glib-2.68:2
+	>=media-video/pipewire-0.3.0:0/0.3
+	app-crypt/libsecret
+	x11-libs/libnotify
+	rdp? (
+		>=net-misc/freerdp-2.3:=[server]
+		>=sys-fs/fuse-3.9.1
+		>=x11-libs/libxkbcommon-1.0.0
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	sed -i -e '/systemd_dep/d' meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use rdp)
+		$(meson_use vnc)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}