[gentoo-commits] repo/proj/guru:dev commit in: dev-libs/fortran-stdlib/

["Sergey Torokhov" <torokhov-s-a@yandex.ru>]

commit:     1fca5f27340ac2e78813e78414a5c14c93f1bf28
Author:     Sergey Torokhov <torokhov-s-a <AT> yandex <DOT> ru>
AuthorDate: Wed Sep 15 22:39:02 2021 +0000
Commit:     Sergey Torokhov <torokhov-s-a <AT> yandex <DOT> ru>
CommitDate: Wed Sep 15 22:39:02 2021 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=1fca5f27

dev-libs/fortran-stdlib: new package live ebuild

There is currently no any releases, maybe later the versions
binded to certain dates will be added.

Signed-off-by: Sergey Torokhov <torokhov-s-a <AT> yandex.ru>

 dev-libs/fortran-stdlib/fortran-stdlib-9999.ebuild | 59 ++++++++++++++++++++++
 dev-libs/fortran-stdlib/metadata.xml               | 11 ++++
 2 files changed, 70 insertions(+)

diff --git a/dev-libs/fortran-stdlib/fortran-stdlib-9999.ebuild b/dev-libs/fortran-stdlib/fortran-stdlib-9999.ebuild
new file mode 100644
index 000000000..4a75181b0
--- /dev/null
+++ b/dev-libs/fortran-stdlib/fortran-stdlib-9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+FORTRAN_STANDARD="2003"
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit cmake fortran-2 git-r3 python-any-r1 toolchain-funcs
+
+EGIT_REPO_URI="https://github.com/fortran-lang/stdlib.git"
+SRC_URI=""
+
+DESCRIPTION="A community driven standard library for (modern) Fortran"
+HOMEPAGE="https://stdlib.fortran-lang.org/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="mirror !test? ( test )"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_any_dep '
+		dev-util/fypp[${PYTHON_USEDEP}]
+	')
+	doc? (
+		$(python_gen_any_dep '
+			app-doc/ford[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	fortran-2_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs+=(
+		-DBUILD_SHARED_LIBS=on
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc ; then
+		einfo "Build API documentation:"
+		${EPYTHON} ford API-doc-FORD-file.md || die
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	use doc && HTML_DOCS=( "${WORKDIR}/${P}"/API-doc/. )
+	einstalldocs
+}

diff --git a/dev-libs/fortran-stdlib/metadata.xml b/dev-libs/fortran-stdlib/metadata.xml
new file mode 100644
index 000000000..836f42bd0
--- /dev/null
+++ b/dev-libs/fortran-stdlib/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>torokhov-s-a@yandex.ru</email>
+		<name>Sergey Torokhov</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">fortran-lang/stdlib</remote-id>
+	</upstream>
+</pkgmetadata>