[gentoo-commits] repo/gentoo:master commit in: app-misc/gramps/

["Marek Szuba" <marecki@gentoo.org>]

commit:     3d1ecc5ca8ff61718cf7207a5cf7f02efad7c74e
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 13 17:09:57 2021 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Mon Sep 13 17:10:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d1ecc5c

app-misc/gramps: remove 5.1.3

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 app-misc/gramps/Manifest            |   1 -
 app-misc/gramps/gramps-5.1.3.ebuild | 110 ------------------------------------
 2 files changed, 111 deletions(-)

diff --git a/app-misc/gramps/Manifest b/app-misc/gramps/Manifest
index 8d31f2c0943..92d6748a3c1 100644
--- a/app-misc/gramps/Manifest
+++ b/app-misc/gramps/Manifest
@@ -1,2 +1 @@
-DIST gramps-5.1.3.tar.gz 17352457 BLAKE2B 8356e29d4e9e2ee78f0f09e54db8f77b2db991652f2c6b2fdc742b8f2e160a2c9c2b7df1a43c34e5d05b12b540e88cd8572fe89cfbb3a1ecb6df650a39ac0651 SHA512 045d5dd6aac4745ce527624657bbee25b9130e63b1b66bdd6a8409cdc876f1f3a4a6c0435d433a62bfffb723f6ac66d93829b79fc12c8768694c266b7a3b82cc
 DIST gramps-5.1.4.tar.gz 17425713 BLAKE2B 9b3761906b70ed6b85112e502290013cf421669418355ed0dc54d00adbcc2af4cd74c596bacaad50cdac6457e7a3b7675d4afb7b471fd471af8b7a6adae3ad82 SHA512 f43fc250142968331db1875260577e022898cff2d1453ee6b74be760d798b75cfdf93492d8d823dbb094da2ddd96a4f249e813c603e7cd9d0585641424284734

diff --git a/app-misc/gramps/gramps-5.1.3.ebuild b/app-misc/gramps/gramps-5.1.3.ebuild
deleted file mode 100644
index b02679ec1bc..00000000000
--- a/app-misc/gramps/gramps-5.1.3.ebuild
+++ /dev/null
@@ -1,110 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{7..9} )
-PYTHON_REQ_USE="sqlite"
-
-DISTUTILS_SINGLE_IMPL=1
-DISTUTILS_USE_SETUPTOOLS=no
-inherit distutils-r1 xdg-utils
-
-DESCRIPTION="Genealogical Research and Analysis Management Programming System"
-HOMEPAGE="https://gramps-project.org/"
-SRC_URI="https://github.com/gramps-project/${PN}/archive/v${PV}.tar.gz
-	-> ${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="berkdb exif geo postscript +rcs +reports spell test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		dev-python/pycairo[${PYTHON_USEDEP}]
-		>=dev-python/pygobject-3.12:3[cairo,${PYTHON_USEDEP}]
-		dev-python/pyicu[${PYTHON_USEDEP}]
-		berkdb? ( dev-python/bsddb3[${PYTHON_USEDEP}] )
-		exif? ( >=media-libs/gexiv2-0.5[${PYTHON_USEDEP},introspection] )
-	')
-	gnome-base/librsvg:2
-	>x11-libs/gtk+-3.14.8:3[introspection]
-	x11-libs/pango[introspection]
-	x11-misc/xdg-utils
-	reports? ( media-gfx/graphviz[postscript?] )
-	geo? ( >=sci-geosciences/osm-gps-map-1.1.0 )
-	spell? ( app-text/gtkspell:3[introspection] )
-	rcs? ( dev-vcs/rcs )
-"
-BDEPEND="test? ( ${RDEPEND}
-	$(python_gen_cond_dep '
-		dev-python/jsonschema[${PYTHON_USEDEP}]
-		dev-python/lxml[${PYTHON_USEDEP}]
-	')
-)"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-5.1.3-test_locale.patch
-)
-
-python_prepare_all() {
-	# Install documentation to the proper location. This can't be done
-	# easily with a patch because we substitute in the ${PF} variable,
-	# and that changes with every revision.
-	sed -i "s:share/doc/gramps:share/doc/${PF}:g" setup.py || die
-	distutils-r1_python_prepare_all
-}
-
-python_configure_all() {
-	mydistutilsargs=(
-		--resourcepath=/usr/share
-		--no-compress-manpages
-	)
-}
-
-python_test_all() {
-	# Gramps builds just fine out of tree but it confuses its test suite.
-	# The following might be an ugly hack but at least it lets the tests
-	# run properly until either I or upstream have come up with something
-	# better. FIXME: test this when a new release comes out.
-	rm -rf "${S}/build" && ln -s "${BUILD_DIR}" "${S}"/build || \
-		die "Failed to symlink build directory to source directory"
-
-	# Set a sane default locale for the tests which do not explicitly set one.
-	local -x LC_ALL=C.UTF-8
-
-	# Note that as of 5.1.3, test failures do not actually propagate back
-	# to this function. For now this is fortunate because the test suite
-	# does not handle the absence of bsddb3 well, in the long run however
-	# this should be fixed.
-	esetup.py test || die
-}
-
-# Ugly hack to work around Bug #717922
-python_install() {
-	local mydistutilsargs=(
-		--resourcepath=/usr/share
-		--no-compress-manpages
-		build
-	)
-	distutils-r1_python_install
-	echo -n "/usr/share" > "${D}$(python_get_sitedir)/gramps/gen/utils/resource-path" || die
-}
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-
-	if use berkdb; then
-		ewarn "The BSDDB back-end in ${PN} has got known stability and data-corruption issues. It has been deprecated since version 5.1.0 and might be removed in 5.2.0."
-		ewarn "If you have any family trees in this format you are highly advised to convert them to SQLite, as described here:"
-		ewarn
-		ewarn "https://gramps-project.org/wiki/index.php/Gramps_5.1_Wiki_Manual_-_Manage_Family_Trees#Converting_a_BSDDB_Family_Tree_to_SQLite"
-	fi
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-}