[gentoo-commits] repo/gentoo:master commit in: net-libs/rabbitmq-c/

["Sam James" <sam@gentoo.org>]

commit:     237b7ac8716b11f799f80ba8cee1cc3f8e7eba57
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 13 00:36:10 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Sep 13 00:36:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=237b7ac8

net-libs/rabbitmq-c: add 0.11.0

Bug: https://bugs.gentoo.org/805374
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-libs/rabbitmq-c/Manifest                 |  1 +
 net-libs/rabbitmq-c/rabbitmq-c-0.11.0.ebuild | 53 ++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/net-libs/rabbitmq-c/Manifest b/net-libs/rabbitmq-c/Manifest
index f78f85b7a96..6e572b6614b 100644
--- a/net-libs/rabbitmq-c/Manifest
+++ b/net-libs/rabbitmq-c/Manifest
@@ -1 +1,2 @@
 DIST rabbitmq-c-0.10.0.tar.gz 145361 BLAKE2B 99b53d5178fa407225d2060584239af83377027fb6a209002d11ed54be4b49bab70ae55c86ab971394ab745a632ece6f070f9c10a9bdd330de4778edbd8e1ea8 SHA512 52a1194fab2dc8698ed065d63898e32aa004a4d68080d4aaf5cb7148cc28ad967283f7a99910d7f054cbba92b487b3a67b839b6f0bd88486ef9be043c9517d4c
+DIST rabbitmq-c-0.11.0.tar.gz 145638 BLAKE2B dce862d132d4bca010dbc284957f34a35d55407ea0eb4fb79369f699207c01cc7ed64c1bd58bea2d1178bd2c02176c3e93b66177fc975175b1da9ab9baaf661f SHA512 0c3dbb6e2b862e9f25e3f76df798ea272bbd81de2865950b95adf1f1e5791eb20d7c9d5a76cb7d2fda54bad5f12bdf69cbfa7e9fd1afdede6f9ec729ca2287de

diff --git a/net-libs/rabbitmq-c/rabbitmq-c-0.11.0.ebuild b/net-libs/rabbitmq-c/rabbitmq-c-0.11.0.ebuild
new file mode 100644
index 00000000000..b8e7ae78e5f
--- /dev/null
+++ b/net-libs/rabbitmq-c/rabbitmq-c-0.11.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="RabbitMQ C client"
+HOMEPAGE="https://github.com/alanxz/rabbitmq-c"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/alanxz/${PN}.git"
+else
+	SRC_URI="https://github.com/alanxz/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/4"
+IUSE="doc test +ssl static-libs tools"
+
+REQUIRED_USE="test? ( static-libs )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="ssl? ( dev-libs/openssl:0= )
+	tools? ( dev-libs/popt )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )
+	tools? ( app-text/xmlto )"
+
+DOCS=( AUTHORS README.md THANKS TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_API_DOCS=$(usex doc)
+		-DBUILD_STATIC_LIBS=$(usex static-libs)
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_TOOLS=$(usex tools)
+		-DBUILD_TOOLS_DOCS=$(usex tools)
+		-DENABLE_SSL_SUPPORT=$(usex ssl)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	pushd "${BUILD_DIR}" > /dev/null || die
+
+	# Skip "basic" test which requires running local rabbitmq-server instance,
+	# see https://github.com/alanxz/rabbitmq-c/issues/530
+	ctest -v -E basic || die
+}