From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1319819-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 8292515808D
for <garchives@archives.gentoo.org>; Fri, 10 Sep 2021 07:22:40 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 6C26EE094A;
Fri, 10 Sep 2021 07:22:39 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 45C18E094A
for <gentoo-commits@lists.gentoo.org>; Fri, 10 Sep 2021 07:22:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 55BFB342554
for <gentoo-commits@lists.gentoo.org>; Fri, 10 Sep 2021 07:22:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 1A578E5
for <gentoo-commits@lists.gentoo.org>; Fri, 10 Sep 2021 07:22:35 +0000 (UTC)
From: "Joonas Niilola" <juippis@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Joonas Niilola" <juippis@gentoo.org>
Message-ID: <1631258546.0ddc65b9d7da18c96081b5fef4548f2b9e0f054d.juippis@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/hydrus/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-gfx/hydrus/Manifest media-gfx/hydrus/hydrus-454.ebuild
X-VCS-Directories: media-gfx/hydrus/
X-VCS-Committer: juippis
X-VCS-Committer-Name: Joonas Niilola
X-VCS-Revision: 0ddc65b9d7da18c96081b5fef4548f2b9e0f054d
X-VCS-Branch: master
Date: Fri, 10 Sep 2021 07:22:35 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 331b34a0-f869-48d9-9455-a3b2938eecda
X-Archives-Hash: 69e7fc850d3c6cbdf7f20d70174ce968
commit: 0ddc65b9d7da18c96081b5fef4548f2b9e0f054d
Author: Ekaterina Vaartis <vaartis <AT> kotobank <DOT> ch>
AuthorDate: Thu Sep 9 11:00:40 2021 +0000
Commit: Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Sep 10 07:22:26 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0ddc65b9
media-gfx/hydrus: Add 454
Signed-off-by: Ekaterina Vaartis <vaartis <AT> kotobank.ch>
Closes: https://github.com/gentoo/gentoo/pull/22253
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>
media-gfx/hydrus/Manifest | 1 +
media-gfx/hydrus/hydrus-454.ebuild | 139 +++++++++++++++++++++++++++++++++++++
2 files changed, 140 insertions(+)
diff --git a/media-gfx/hydrus/Manifest b/media-gfx/hydrus/Manifest
index 0e7ecc4140d..2be93a9c5d4 100644
--- a/media-gfx/hydrus/Manifest
+++ b/media-gfx/hydrus/Manifest
@@ -1,3 +1,4 @@
DIST hydrus-451.tar.gz 38867387 BLAKE2B 80a7139ebcc1447b8eb35754dd65b54127a2b5107bbb8bdb371476f9db984bcd5b9ff388ec726ed5fca31acf69a180c288e1c6cdfabfdef1c72772402d22f3f0 SHA512 482095c03d44979e99e4f3027fa9b6f5c9b90692e29a28246f1e0b4c6fa20c6ed3b1d9e421d3b9bb723a094c1f0aea6aa7468247e23b54570ee99e26dce41654
DIST hydrus-452.tar.gz 38873698 BLAKE2B 3c9c5fc63533f9c94ff3425b8767bffacb20c435f7a904de1229ec3cb079d86009c971515461d55f947743c705b12eee798160cbae04f0c3af283666a82ac482 SHA512 5c0280ae80b9af32629f6a2bcab3466abd01eea502034ac2354e3efabfd7bbe5ae5582950a19d9f28019b993f847000aa194a0b810f4d32b143b24e589de9f66
DIST hydrus-453.tar.gz 38880317 BLAKE2B 93b29d3c973aa583cb6dd32abf94df199aefa9c49137b8137e144a891fbdf9db1cdfb0ec4d378d35e0a07d488a94828bb261c26de3b61b5460d208921c56d194 SHA512 6da364c6f9de9f838d9b3dcc02107bd3d089fde420f4e04086f094e47246e6949c27791a816dc99659db77acad3ca8f7578dc16749eb8b13cfafd7b6c044f5a1
+DIST hydrus-454.tar.gz 38886940 BLAKE2B 38fe5b3483c13dfbf82e636be1e743bb6af6f340a86d5ea69f0e71f7452cd3506b076cf4d6f460e0a1896f0839be7494028a0cbb5f567001af025cd436cf5c45 SHA512 87971c45bc11e7eaba2e08255ca23600406124bd73d6d8d4800ec67135a0d74b5ca7fc8a8a159dbdc89f70702760469c8d719de11f5bf943f7679978a790c456
diff --git a/media-gfx/hydrus/hydrus-454.ebuild b/media-gfx/hydrus/hydrus-454.ebuild
new file mode 100644
index 00000000000..0915a2ae543
--- /dev/null
+++ b/media-gfx/hydrus/hydrus-454.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 desktop optfeature
+
+DESCRIPTION="A booru-like media organizer for the desktop"
+HOMEPAGE="https://hydrusnetwork.github.io/hydrus/ https://github.com/hydrusnetwork/hydrus"
+
+if [[ "${PV}" == "9999" ]]; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/hydrusnetwork/hydrus.git"
+else
+ SRC_URI="https://github.com/hydrusnetwork/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+ KEYWORDS="~amd64"
+fi
+
+# hydrus itself is WTFPL
+# icons included are CC-BY-2.5
+LICENSE="WTFPL-2 CC-BY-2.5"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+# RDEPEND is sorted as such:
+# - No specific requirements
+# - Specific version or slot
+RDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/cloudscraper[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/psutil[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/pyside2[widgets,gui,${PYTHON_USEDEP}]
+ dev-python/python-mpv[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/send2trash[${PYTHON_USEDEP}]
+ dev-python/service_identity[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/twisted[${PYTHON_USEDEP}]
+ media-libs/opencv[python,png,jpeg,${PYTHON_USEDEP}]
+ media-video/ffmpeg
+ media-video/mpv[libmpv,${PYTHON_USEDEP}]
+
+ >=dev-python/QtPy-1.9.0-r4[pyside2,${PYTHON_USEDEP}]
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ ')
+"
+BDEPEND="
+ ${RDEPEND}
+ $(python_gen_cond_dep '
+ test? (
+ dev-python/httmock[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+ )
+ ')
+"
+
+PATCHES=(
+ "${FILESDIR}/userpath-in-local-share.patch"
+)
+
+src_prepare() {
+ default
+
+ # Contains pre-built binaries for other systems and a broken swf renderer for linux
+ rm -r bin/ || die
+ # Build files used for CI, not actually needed
+ rm -r static/build_files || die
+ # Duplicate license file, not needed
+ rm license.txt || die
+ # Python requirements files, not needed
+ rm requirements_*.txt || die
+}
+
+src_compile() {
+ python_optimize "${S}"
+}
+
+src_test() {
+ # The tests use unittest, but are run with a custom runner script.
+ # QT_QPA_PLATFORM is required to make them run without X
+ local -x QT_QPA_PLATFORM=offscreen
+ "${EPYTHON}" "${S}/test.py" || die "Tests failed"
+}
+
+src_install() {
+ local doc="${EPREFIX}/usr/share/doc/${PF}"
+ elog "Hydrus includes an excellent manual, that can either be viewed at"
+ elog "${doc}/html/help/index.html"
+ elog "or accessed through the hydrus help menu."
+
+ mv "help my client will not boot.txt" "help_my_client_will_not_boot.txt" || die
+
+ local DOCS=(COPYING README.md Readme.txt help_my_client_will_not_boot.txt db/)
+ local HTML_DOCS=("${S}"/help/)
+ einstalldocs
+
+ # Files only needed for testing
+ rm test.py hydrus/hydrus_test.py || die
+ rm -r hydrus/test/ static/testing/ || die
+
+ # These files are copied into doc
+ rm -r "${DOCS[@]}" "${HTML_DOCS[@]}" || die
+ # The program expects to find documentation here, so add a symlink to doc
+ dosym "${doc}/html/help" /opt/hydrus/help
+
+ insinto /opt/hydrus
+ doins -r "${S}"/.
+
+ exeinto /usr/bin
+ python_newexe - hydrus-server < <(sed "s/python/${EPYTHON}/" "${FILESDIR}/hydrus-server" || die)
+ python_newexe - hydrus-client < <(sed "s/python/${EPYTHON}/" "${FILESDIR}/hydrus-client" || die)
+
+ make_desktop_entry "hydrus-client" "Hydrus Client" "/opt/hydrus/static/hydrus_non-transparent.png" \
+ "AudioVideo;FileTools;Graphics;Network;"
+}
+
+pkg_postinst() {
+ optfeature "automatic port forwarding support" "net-libs/miniupnpc"
+ optfeature "bandwidth charts support" "dev-python/pyside2[charts]"
+ optfeature "memory compression in the client" "dev-python/lz4"
+ optfeature "SOCKS proxy support" "dev-python/requests[socks5]" "dev-python/PySocks"
+}