[gentoo-commits] proj/sci:master commit in: dev-python/jupyter-lsp/

[gentoo-commits] proj/sci:master commit in: dev-python/jupyter-lsp/

[Andrew Ammerlaan]

commit:     997f7607fcbf357c8f552bbb163053cdff4f333b
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  8 10:45:52 2021 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed Sep  8 10:45:52 2021 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=997f7607

dev-python/jupyter-lsp: add package

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/jupyter-lsp/jupyter-lsp-1.4.1.ebuild | 42 +++++++++++++++++++++++++
 dev-python/jupyter-lsp/metadata.xml             |  8 +++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/jupyter-lsp/jupyter-lsp-1.4.1.ebuild b/dev-python/jupyter-lsp/jupyter-lsp-1.4.1.ebuild
new file mode 100644
index 000000000..613baae8b
--- /dev/null
+++ b/dev-python/jupyter-lsp/jupyter-lsp-1.4.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Multi-Language Server WebSocket proxy for Jupyter Notebook/Lab"
+HOMEPAGE="https://github.com/krassowski/jupyterlab-lsp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/entrypoints[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_server-1.1.2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not depend on pytest-cov or flake8
+	sed -i -e '/--cov/d' -e '/--flake8/d' setup.cfg || die
+	# R lsp server not packaged
+	sed -i -e 's:test_r_package_detection:_&:' \
+		jupyter_lsp/tests/test_detect.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	optfeature "Language server for Python" dev-python/python-lsp-server
+}

diff --git a/dev-python/jupyter-lsp/metadata.xml b/dev-python/jupyter-lsp/metadata.xml
new file mode 100644
index 000000000..ae9640ffb
--- /dev/null
+++ b/dev-python/jupyter-lsp/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>sci@gentoo.org</email>
+		<name>Gentoo Science Project</name>
+	</maintainer>
+</pkgmetadata>