[gentoo-commits] repo/proj/guru:master commit in: dev-lang/fbc/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     660747b31c9078e4a759c340857668c698354153
Author:     William Breathitt Gray <vilhelm.gray <AT> gmail <DOT> com>
AuthorDate: Wed Sep  8 02:36:55 2021 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Sep  8 02:37:24 2021 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=660747b3

dev-lang/fbc: Version bump to 1.08.1

Signed-off-by: William Breathitt Gray <vilhelm.gray <AT> gmail.com>

 dev-lang/fbc/Manifest          |  1 +
 dev-lang/fbc/fbc-1.08.1.ebuild | 61 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-lang/fbc/Manifest b/dev-lang/fbc/Manifest
index f56b456a5..6416dd34b 100644
--- a/dev-lang/fbc/Manifest
+++ b/dev-lang/fbc/Manifest
@@ -1 +1,2 @@
 DIST fbc-1.07.3.tar.gz 9035460 BLAKE2B c0356c36ebd455954993ce5d4a983d06c33abc5bf0a059a44832d441514643c7d08e40268a7b3b9a0cba21368058199be395cc28dd7f87df23d576f78aece276 SHA512 6040248c433db3191678209401ff4a643c500d967d67352f1aeca347648056b0a2cdef25bbb7532fec0351a13984c72e80cb7b00faf3ead6c219422955d148fb
+DIST fbc-1.08.1.tar.gz 9395903 BLAKE2B 303def97f5e1c77f4941c6d08ed251b296dbc97f7e549f863feddd2775cf390962cda42e1751c647c560299f02ea60d29b312301faa78fbd6bba6ae8ab75f220 SHA512 1c56f4e1a56e0cfc309e5748e83a2ee98fe97a509e6fd3a7f51b1805a4cc40fefc3884b4434a62404c05001c84fdfa8b4e3debbfdb188ab42652a7a4020baea6

diff --git a/dev-lang/fbc/fbc-1.08.1.ebuild b/dev-lang/fbc/fbc-1.08.1.ebuild
new file mode 100644
index 000000000..4c2681646
--- /dev/null
+++ b/dev-lang/fbc/fbc-1.08.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A free/open source, multi-platform BASIC compiler."
+HOMEPAGE="https://www.freebasic.net"
+SRC_URI="https://github.com/freebasic/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="FDL-1.2 GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gpm libffi opengl X"
+
+DEPEND="
+	sys-libs/ncurses:=
+	gpm? ( sys-libs/gpm )
+	libffi? ( dev-libs/libffi )
+	opengl? ( virtual/opengl )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXpm
+		x11-libs/libXrandr
+		x11-libs/libXrender
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="|| (
+		dev-lang/fbc
+		dev-lang/fbc-bootstrap )"
+
+DOCS="${S}/doc/fbc.1"
+
+src_compile() {
+	local xcflags=(
+		$(usex gpm "" "-DDISABLE_GPM")
+		$(usex libffi "" " -DDISABLE_FFI")
+		$(usex opengl "" " -DDISABLE_OPENGL")
+		$(usex X "" " -DDISABLE_X11")
+	)
+
+	local fbc="fbc"
+	local fbcflags=""
+	# fbc requires a space after the -Wl option
+	local fblflags="${LDFLAGS//-Wl,/-Wl }"
+
+	if has_version -b dev-lang/fbc-bootstrap; then
+		fbc="fbc-bootstrap"
+		fbcflags="-prefix ${EPREFIX}/usr/share/freebasic-bootstrap"
+		fblflags+=" -prefix ${EPREFIX}/usr/share/freebasic-bootstrap"
+	fi
+
+	# Build fbc
+	emake CFLAGS="${CFLAGS} ${xcflags[*]} -I/usr/$(get_libdir)/libffi/include" FBC="${fbc}" FBCFLAGS="${fbcflags}" FBLFLAGS="${fblflags}" TARGET="${CHOST}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="/usr" TARGET="${CHOST}" install
+	einstalldocs
+}