[gentoo-commits] repo/gentoo:master commit in: dev-util/vulkan-tools/

["Nick Sarnie" <sarnex@gentoo.org>]

commit:     3fd5162736fa05242fa4b22c0d42bf8171a7cdec
Author:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Sun Sep  5 01:59:02 2021 +0000
Commit:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Sun Sep  5 02:04:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3fd51627

dev-util/vulkan-tools: Version bump

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>

 dev-util/vulkan-tools/Manifest                    |  1 +
 dev-util/vulkan-tools/vulkan-tools-1.2.189.ebuild | 86 +++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 28011bd0b0e..0bed409c5a7 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1 +1,2 @@
 DIST vulkan-tools-1.2.182.tar.gz 847991 BLAKE2B 5ab9d73383338bcc3c54487f0f433466d9974269d3be2aa0d50281affeee8fb94414eb638fc94be6fd2dc059c0a2d3dca4e9a8caf3e2b8758c03c57373e2f73b SHA512 5cc9500923288641529556e82a708b88f7dc775c75166d10ae2a807562ce9dda3993aa01a261ff4f9c2cc31ea47423a12f21ec64d32e6aee66ef7c3fc2dc17fc
+DIST vulkan-tools-1.2.189.tar.gz 849041 BLAKE2B ae38aaca9789276bcb93c5c297c9113fcced4cd3417f0619c0e1fb539df5891e725a77785fbeca0c8957644af7245ff9f0a3981cf5f8726f4f231e39f05ddfbb SHA512 3ac4f79a6ba18690026d1933b7f3c45769f9759e25d19508bc34d431454dc548e1f738ae3d804db2864a97de3b8628f167bc00dcad4059eaeb1714e4fdd3507a

diff --git a/dev-util/vulkan-tools/vulkan-tools-1.2.189.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.2.189.ebuild
new file mode 100644
index 00000000000..82f33ec2490
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.2.189.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Tools
+CMAKE_ECLASS="cmake-utils"
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=( python3_{8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+# Cube demo only supports one window system at a time
+REQUIRED_USE="cube? ( ^^ ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-util/cmake-3.10.2
+	cube? ( dev-util/glslang:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	>=media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+
+	use cube && mycmakeargs+=(
+		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
+		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}