[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-commander/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     4bcda1303c7938686319f291646e20a290cfde6c
Author:     Uwe Scholz <u.scholz83 <AT> gmx <DOT> de>
AuthorDate: Sat Aug 28 20:23:21 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Sep  2 12:54:32 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bcda130

gnome-extra/gnome-commander: add 1.12.2

Signed-off-by: Uwe Scholz <u.scholz83 <AT> gmx.de>

Closes: https://bugs.gentoo.org/808516
Closes: https://github.com/gentoo/gentoo/pull/22148
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 gnome-extra/gnome-commander/Manifest               |  1 +
 .../gnome-commander/gnome-commander-1.12.2.ebuild  | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/gnome-extra/gnome-commander/Manifest b/gnome-extra/gnome-commander/Manifest
index 944ba1a67dc..00ba7ade584 100644
--- a/gnome-extra/gnome-commander/Manifest
+++ b/gnome-extra/gnome-commander/Manifest
@@ -1 +1,2 @@
 DIST gnome-commander-1.12.1.tar.xz 7532412 BLAKE2B 92a4c71e716aca5354cd53ca10440ce11426f9baa11342c37a8dbd5d3fe2898ea9e7aa577d584d0e91e85a8213a5480dd045c6d0ffbd05155b05d74c2a0b52e7 SHA512 74756af9a720ab81904e3f7834ae008af67d635cc1d1b961420d02c029616465dfe06a18bc5b443d0a9725cfefe6e9f7cdba68faa62515f8ccb85a2246867010
+DIST gnome-commander-1.12.2.tar.xz 7529048 BLAKE2B 468279fcfd25111c673d7ce75124bb4b1773c74952759f749e6e526c0525ec801484a9be01f5819942302d634c7427b313e25fea85c3d792d66967d4edf92ca7 SHA512 0f56450a09fcf8a73cc31e91564b133fd5fd199ea75c9376a2c329e070554c2c3ae4916f899940f92ddea5fff29656c9485a207dd22a28f1cda12a46f4cab32c

diff --git a/gnome-extra/gnome-commander/gnome-commander-1.12.2.ebuild b/gnome-extra/gnome-commander/gnome-commander-1.12.2.ebuild
new file mode 100644
index 00000000000..6c407b4f188
--- /dev/null
+++ b/gnome-extra/gnome-commander/gnome-commander-1.12.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 optfeature toolchain-funcs
+
+DESCRIPTION="A graphical, full featured, twin-panel file manager"
+HOMEPAGE="https://gcmd.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="chm exif gsf pdf samba taglib test +unique"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/yelp-tools
+	>=dev-libs/glib-2.62.0:2
+	>=gnome-base/gnome-vfs-2.0.0
+	>=x11-libs/gtk+-2.24.0:2
+	chm? ( dev-libs/chmlib )
+	exif? ( >=media-gfx/exiv2-0.14 )
+	gsf? ( >=gnome-extra/libgsf-1.12.0 )
+	pdf? ( >=app-text/poppler-0.18 )
+	samba? ( >=gnome-base/gnome-vfs-2.0.0[samba] )
+	taglib? ( >=media-libs/taglib-1.4 )
+	unique? ( >=dev-libs/libunique-0.9.3:1 )
+"
+BDEPEND="
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.7.0 )
+"
+
+pkg_pretend() {
+	if tc-is-gcc && [[ $(gcc-major-version) -lt 8 ]]; then
+		eerror "Compilation with gcc older than version 8 is not supported"
+		die "GCC too old, please use gcc-8 or above"
+	fi
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_with chm libchm) \
+		$(use_with exif exiv2) \
+		$(use_with gsf libgsf) \
+		$(use_with pdf poppler) \
+		$(use_with samba) \
+		$(use_with taglib) \
+		$(use_with unique)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	optfeature "synchronizing files and directories" dev-util/meld
+	optfeature "viewing the documentation" gnome-extra/yelp
+}