[gentoo-commits] repo/gentoo:master commit in: dev-libs/opensc/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     c79a0efb8bd4595d843b4bdaa1a1c4b4f233b7d9
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  1 11:58:25 2021 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Wed Sep  1 11:59:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c79a0efb

dev-libs/opensc: add 0.22.0

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 dev-libs/opensc/Manifest             |  1 +
 dev-libs/opensc/opensc-0.22.0.ebuild | 65 ++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-libs/opensc/Manifest b/dev-libs/opensc/Manifest
index c25c8a7d762..bbd5aee1092 100644
--- a/dev-libs/opensc/Manifest
+++ b/dev-libs/opensc/Manifest
@@ -1 +1,2 @@
 DIST opensc-0.21.0.tar.gz 2210878 BLAKE2B 22b63ca59cb721cdbbda755fa90f5b46fd9e5b6d7768cddbfeaffd58d68adcb145d6d604b334cf778608be9ee5fc98109f98d131d2536e61f79705aa3dbafa6c SHA512 3511b0a04a96e62011c48667e3fd36a1611fe67a89f7626ff056c9c3614f8cabc91c9924a6ca7a8ea50076a128e3967277a0dd624b4fa27c62cefee9fab22646
+DIST opensc-0.22.0.tar.gz 2287020 BLAKE2B 74e4bb6843b640c5a397b820a52180a34159c330f5ecb81af166096f23e2499ef1a4d555b5d71613da57ba121d0f984dcfdc2ba9491f26f826a423725a2321e2 SHA512 70ad5f1219f2ec2a5529a30d8e9955510c77c87d0bc857d5951c7227c75cf9de1c6071f43dd3816a2034123ebd902709793ff776e84d5379fdd54c811ccfaaee

diff --git a/dev-libs/opensc/opensc-0.22.0.ebuild b/dev-libs/opensc/opensc-0.22.0.ebuild
new file mode 100644
index 00000000000..40c261f055b
--- /dev/null
+++ b/dev-libs/opensc/opensc-0.22.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 libtool
+
+DESCRIPTION="Libraries and applications to access smartcards"
+HOMEPAGE="https://github.com/OpenSC/OpenSC/wiki"
+SRC_URI="https://github.com/OpenSC/OpenSC/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="ctapi doc openct notify +pcsc-lite readline secure-messaging ssl test zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="zlib? ( sys-libs/zlib )
+	readline? ( sys-libs/readline:0= )
+	ssl? ( dev-libs/openssl:0= )
+	openct? ( >=dev-libs/openct-0.5.0 )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )
+	notify? ( dev-libs/glib:2 )"
+DEPEND="${RDEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	test? ( dev-util/cmocka )"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	pcsc-lite? ( !openct !ctapi )
+	openct? ( !pcsc-lite !ctapi )
+	ctapi? ( !pcsc-lite !openct )
+	|| ( pcsc-lite openct ctapi )"
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--with-completiondir="$(get_bashcompdir)" \
+		--disable-openpace \
+		--disable-static \
+		--disable-strict \
+		--enable-man \
+		$(use_enable ctapi) \
+		$(use_enable doc) \
+		$(use_enable notify ) \
+		$(use_enable openct) \
+		$(use_enable pcsc-lite pcsc) \
+		$(use_enable readline) \
+		$(use_enable secure-messaging sm) \
+		$(use_enable ssl openssl) \
+		$(use_enable test cmocka) \
+		$(use_enable zlib)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+	insinto /etc/pkcs11/modules/
+	doins "${FILESDIR}/${PN}.module"
+}