[gentoo-commits] repo/gentoo:master commit in: dev-util/umockdev/

["Matt Turner" <mattst88@gentoo.org>]

commit:     8c7b220ef5e672d41c669ecc77499ceb4c63e93c
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 28 19:09:49 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Aug 28 21:14:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8c7b220e

dev-util/umockdev: Version bump to 0.16.2

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-util/umockdev/Manifest               |  1 +
 dev-util/umockdev/umockdev-0.16.2.ebuild | 53 ++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index c6d45dc28fc..0ce3fdf45d7 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1,2 +1,3 @@
 DIST umockdev-0.12.1.tar.xz 756920 BLAKE2B a8c1d9734f4c0a8e7f19405e011ce964efce6621b4886efead88e040bfe07d2f5a85f063977dfed1c8fb5a5bf4668024b6e687b688a9609cdba1db419518a8ac SHA512 a8995d09179c7d2d37d319f8e675fb15c3caa605c57b56cbb2e785088909d886e790864475feb82ab2b6eb2449038c636a06250d4f9eb8b28b38f0d80574824c
 DIST umockdev-0.16.1.tar.xz 478308 BLAKE2B 3d49ca1d9c9b7573ac63f5f7ecd81071041597732b507619c333379095434ac55eb26f16bdf5897b94bbeb5c307a34b703accd220cd6202482e172dd3a6d1983 SHA512 baeaf05cc6b8d8e2a5cae16b808db759a18a969cea0f2ceed5f6c2521edc0c4c07dc16265a4821051de51f4314fd39d63ebf2da124fcd3e103ec743dadfedaa8
+DIST umockdev-0.16.2.tar.xz 478388 BLAKE2B 8fb2116ec7d48b238898052d959c596f4f91a65cf7b8292de8b8731e6fe50600282cb56093b8d6ca1afdc082a12c9af3c4a4f443283538ffb2aeae4c2b775596 SHA512 82020c068d5a158a762f865f4b25d1ee8596785a5b379c316c652004e1b1b9c533d4dad87818a490f89983a4c065f34e4ff5ca91360bac6d79b141dfa2139eea

diff --git a/dev-util/umockdev/umockdev-0.16.2.ebuild b/dev-util/umockdev/umockdev-0.16.2.ebuild
new file mode 100644
index 00000000000..d57690e716c
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.16.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_src_prepare
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}