[gentoo-commits] repo/gentoo:master commit in: dev-python/kombu/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     fd644f5d0dfeb2f72852a0bc1ba39d22fc8b7a94
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 22 06:47:32 2021 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sun Aug 22 06:59:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fd644f5d

dev-python/kombu: add 5.1.0, major cleanup

- enable py3.9
- Move from USE flags to optfeature and test dep
- use distutils_enable_sphinx
- use distutils_enable_tests
- disable problematic tests depending on unpackaged modules
- add more optional backends

Closes: https://bugs.gentoo.org/800659
Closes: https://bugs.gentoo.org/805197
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/kombu/Manifest           |  1 +
 dev-python/kombu/kombu-5.1.0.ebuild | 77 +++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index b767a8f4c93..d69a3bfeb53 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.0.1.tar.gz 404428 BLAKE2B 89d4c2daf70c3dcd0a990c8f045074780f2d4f13f39899c0ab3b73b473948469746cf8872aaa8565f5c4b071bf18ff510cd565e8f9b6a3735a0bf1d0af55e9b6 SHA512 aa5d35b7753f5ec8d95512c322fabf0163628b9afbd228faa2be910a1cd4ea3236a7e43485e17650e1aa9aebae59a91a2b0bdc1950e4e4c622b499a4ae29ea0e
+DIST kombu-5.1.0.tar.gz 416353 BLAKE2B 2c26aac0a8eda62475e2a9a859b2548046dfce0699a8dafce3cc6471ee3b82f82882a53903a86f69cf16f948e4d0e66f379479f7f1f46aca2bcbdd031ba87811 SHA512 62ef16e8e3fb592882b8060f29b95e7224ba635132ed688eece0c2d254e7f7fb525c778cac23f15495464c6dbcf84d7a1372fde6f55fcfe66677cf43d3e9d4de

diff --git a/dev-python/kombu/kombu-5.1.0.ebuild b/dev-python/kombu/kombu-5.1.0.ebuild
new file mode 100644
index 00000000000..5d90881cb0c
--- /dev/null
+++ b/dev-python/kombu/kombu-5.1.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1 optfeature
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.org/project/kombu/ https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.0.6[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/kazoo[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-3.3.0[${PYTHON_USEDEP}]
+		dev-python/pyro:4[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-3.3.11[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_celery
+
+EPYTEST_IGNORE=(
+	# Unpackaged azure-servicebus
+	t/unit/transport/test_azureservicebus.py
+	# Unpackaged librabbitmq
+	t/unit/transport/test_librabbitmq.py
+	# Unpackaged python-consul
+	t/unit/transport/test_consul.py
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	t/unit/transport/test_etcd.py
+)
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Pyro 4 backend" dev-python/pyro:4
+	optfeature "Redis backend" dev-python/redis-py
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "Zookeeper backend" dev-python/kazoo
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}