[gentoo-commits] repo/gentoo:master commit in: dev-python/tox/

["Michał Górny" <mgorny@gentoo.org>]

commit:     ff475d75312715cd882caa351125e36d9ec790c2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 19 06:40:34 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 19 06:57:21 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff475d75

dev-python/tox: Bump to 3.24.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/tox/Manifest          |  1 +
 dev-python/tox/tox-3.24.2.ebuild | 69 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 59b7edbdc4c..9769df5375c 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-3.24.1.tar.gz 305886 BLAKE2B fcedf8054a19a79045b2edead599fb11b7942986fa4bbc184140603e3bc6700eada452e661f4a576d029804ab2a9282df0cf9198eee9b483c2c6c68b086ee156 SHA512 e4bfb3dab15887ce6432a91b88a7387179cbf2a5ab5fa608b3f1f7349be4122d76ce01d396ae9b1515c211f2905d110a8414e254cc72bcf8a74542db98ea52de
+DIST tox-3.24.2.tar.gz 305924 BLAKE2B f91af9fdb4de94eb9ecf65774619234f1e52827c7c6e3ce75ca8161564f8cdc8af210f229ae07f5d381f7964cbbc936f47d4242848513c9bf1c8989a73fe0420 SHA512 e33a1126440ac53cf07cd7dbe695ea1307ebad92e0ed4d6e6c738affa059104f1b5bfc360883283ddd59e5156f7bb00c52d2d2ddd2294b6664f22a2abaaf66c3

diff --git a/dev-python/tox/tox-3.24.2.ebuild b/dev-python/tox/tox-3.24.2.ebuild
new file mode 100644
index 00000000000..1e0885d735e
--- /dev/null
+++ b/dev-python/tox/tox-3.24.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-1.1[${PYTHON_USEDEP}]
+	' pypy3)
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local deselect=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && deselect+=(
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+
+		# broken without tox installed first
+		# TODO: why it can't import itself?
+		tests/integration/test_parallel_interrupt.py::test_parallel_interrupt
+	)
+
+	distutils_install_for_testing --via-venv
+	epytest --no-network ${deselect[@]/#/--deselect }
+}