[gentoo-commits] repo/gentoo:master commit in: dev-python/pyglet/

["Michał Górny" <mgorny@gentoo.org>]

commit:     3f64bc6f038358f94539771c559f4ddf4079aa32
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 18 06:32:45 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Aug 18 06:56:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3f64bc6f

dev-python/pyglet: Bump to 1.5.19

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyglet/Manifest             |  1 +
 dev-python/pyglet/pyglet-1.5.19.ebuild | 61 ++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/pyglet/Manifest b/dev-python/pyglet/Manifest
index 354e13da740..7aa18027160 100644
--- a/dev-python/pyglet/Manifest
+++ b/dev-python/pyglet/Manifest
@@ -1 +1,2 @@
 DIST pyglet-1.5.18.tar.gz 6440818 BLAKE2B cb7832000e0df96cd794f8eff9ba41aac8571542fbc45d1607df3935a7ed53ba8fd46b6bba40f6d5d53adfb2024aad1930cba1889b5d40d342457f7dc06db5d1 SHA512 d6ceddecccb36a90bef38c4a1608e866bb90ebb72eaaff693a2eb34678c7a50c99213a69042c569c22d54cc04a4b11d37ea8da47425958505261ebcf99bd28ce
+DIST pyglet-1.5.19.tar.gz 6446786 BLAKE2B fef21122cf31718e0a796b3be4edf386bf477dc4fa6480970159b9d361e489417c9cad1df1060290bc1678408eed36e287c15da442275beaa8d354c268568411 SHA512 7ef85d91cdcafef8cf097e96bd34e800002824696ffbc1132c2dd776fe9d3c7be0b5633fff1cb10344fcc1aafa3c0c9a75547ad374be091f35aa99527869ab4b

diff --git a/dev-python/pyglet/pyglet-1.5.19.ebuild b/dev-python/pyglet/pyglet-1.5.19.ebuild
new file mode 100644
index 00000000000..247321eafd3
--- /dev/null
+++ b/dev-python/pyglet/pyglet-1.5.19.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Cross-platform windowing and multimedia library for Python"
+HOMEPAGE="http://pyglet.org/"
+SRC_URI="https://github.com/pyglet/pyglet/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples image +sound"
+
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/gst-python[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	image? ( || (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		x11-libs/gtk+:2
+	) )
+	sound? ( || (
+		media-libs/openal
+		media-sound/pulseaudio
+	) )
+"
+#	ffmpeg? ( media-libs/avbin-bin )
+
+DOCS=( DESIGN NOTICE README.md RELEASE_NOTES )
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	xdg_environment_reset
+
+	# Specify path to avoid running interactive tests
+	# We could add in integration tests, but they're slow
+	epytest tests/unit
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}