[gentoo-commits] repo/gentoo:master commit in: dev-libs/libowfat/

["Sam James" <sam@gentoo.org>]

commit:     a9f0cfb4a1c457e47c02ef052599e7e58d0c3ba8
Author:     Rolf Eike Beer <eike <AT> sf-mail <DOT> de>
AuthorDate: Thu Aug 12 08:50:28 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Aug 16 01:58:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a9f0cfb4

dev-libs/libowfat: EAPI 8

Signed-off-by: Rolf Eike Beer <eike <AT> sf-mail.de>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libowfat/libowfat-0.32-r3.ebuild | 49 +++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-libs/libowfat/libowfat-0.32-r3.ebuild b/dev-libs/libowfat/libowfat-0.32-r3.ebuild
new file mode 100644
index 00000000000..45a2efd5c74
--- /dev/null
+++ b/dev-libs/libowfat/libowfat-0.32-r3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="reimplement libdjb - excellent libraries from Dan Bernstein"
+SRC_URI="https://www.fefe.de/${PN}/${P}.tar.xz"
+HOMEPAGE="https://www.fefe.de/libowfat/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86"
+IUSE="diet"
+
+RDEPEND="diet? ( >=dev-libs/dietlibc-0.33_pre20090721 )"
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc10.patch
+)
+
+pkg_setup() {
+	# Required for mult/umult64.c to be usable
+	append-flags -fomit-frame-pointer
+}
+
+src_compile() {
+	emake \
+		CC=$(tc-getCC) \
+		CFLAGS="-I. ${CFLAGS}" \
+		DIET="${EPREFIX}/usr/bin/diet -Os" \
+		prefix="${EPREFIX}/usr" \
+		INCLUDEDIR="${EPREFIX}/usr/include" \
+		$( use diet || echo 'DIET=' )
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		MAN3DIR="${EPREFIX}/usr/share/man/man3" \
+		INCLUDEDIR="${EPREFIX}/usr/include" \
+		install
+
+	mv "${ED}"/usr/share/man/man3/{buffer.3,owfat-buffer.3} || die
+}