[gentoo-commits] repo/gentoo:master commit in: app-cdr/dolphin-plugins-mountiso/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     51b1b93263571bf0a3805258c3e6c077a46493a8
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 12 09:48:50 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Aug 12 10:18:51 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=51b1b932

app-cdr/dolphin-plugins-mountiso: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-cdr/dolphin-plugins-mountiso/Manifest          |  1 +
 .../dolphin-plugins-mountiso-21.08.0.ebuild        | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index 7f0c6648b4b..1cb60bbf0ea 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-21.04.3.tar.xz 253244 BLAKE2B c5c0e302dfc4eb82e2de1a635824bf8fd2c70bcac65c261253f0e52e7d9242fa339fe2dc619b927b0379477b2c80a22ec210080af8f2370e0a0182af3347df6a SHA512 e4beba0d596782951b149d42e930d76b12a36bea83f35eb0cff9e49b3e02d4b2aa55f4245d4b8708044a49770d477badc964752828eef4caeaefd4f16e5f9dad
+DIST dolphin-plugins-21.08.0.tar.xz 252708 BLAKE2B 7e6d4c72b0527302737a9e636a6e672699868325af4ef763a7595677e4f0ba3dc1e8cbcbcbe4db92becf481f9746ac61257e1d2c91fb145059724c9e70497f0a SHA512 46448d35e0d599c373f990a9cdc6bac91a6acb1bdd871e73ced298ae6be3c9187be12a3ffcc7734c9d87f8825adae472d5d923f46bf15d0b2c012b2d5b755a92

diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.08.0.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.08.0.ebuild
new file mode 100644
index 00000000000..85a23784c1a
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.08.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.84.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}