[gentoo-commits] repo/gentoo:master commit in: net-mail/mailutils/

["Eray Aslan" <eras@gentoo.org>]

commit:     f98d66f67b8b5f810220b9d66916ecd3fe31daef
Author:     Eray Aslan <eras <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  6 10:21:21 2021 +0000
Commit:     Eray Aslan <eras <AT> gentoo <DOT> org>
CommitDate: Fri Aug  6 10:21:21 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f98d66f6

net-mail/mailutils: bump to 3.13

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Eray Aslan <eras <AT> gentoo.org>

 net-mail/mailutils/Manifest              |   1 +
 net-mail/mailutils/mailutils-3.13.ebuild | 141 +++++++++++++++++++++++++++++++
 2 files changed, 142 insertions(+)

diff --git a/net-mail/mailutils/Manifest b/net-mail/mailutils/Manifest
index 69879191624..91f34b18d84 100644
--- a/net-mail/mailutils/Manifest
+++ b/net-mail/mailutils/Manifest
@@ -1 +1,2 @@
 DIST mailutils-3.12.tar.xz 3134484 BLAKE2B eac7934e9332482adffa3d4b1574d89a65949644ca8dd14e507e9c5f268d485b97f4d61deadf34b2ddcae1b91deee93372e9ebd53c88a0c0092346a0d83fd67e SHA512 a7d681bc7a763b7f09b704c8a536ea1c2444c52ca736eca321ca72fd32e2e62c0e14687ba79654d9162d45189d0621b1c75c639b81e04a79bbf3b3c09b9cebd2
+DIST mailutils-3.13.tar.xz 3152892 BLAKE2B cd7d9ce0391d85482581eeb52f60fcc175647d21e433a4dacee3547aa4dcd710331ad780b6706c242d1a7501ec7fc50ff0c25f9b5f4ceeed84893c637ca366c1 SHA512 fd0b23aa535c6446af1ae633d68d41d1aa243d489b2623d346f6a0d6b543c43ab6c2b9bb1449d664abacbcd3ec3a0a5e7a0a5d56d2762e8a961544c77ccc592a

diff --git a/net-mail/mailutils/mailutils-3.13.ebuild b/net-mail/mailutils/mailutils-3.13.ebuild
new file mode 100644
index 00000000000..823273c3589
--- /dev/null
+++ b/net-mail/mailutils/mailutils-3.13.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit autotools elisp-common eutils flag-o-matic python-single-r1 toolchain-funcs
+
+DESCRIPTION="A useful collection of mail servers, clients, and filters"
+HOMEPAGE="https://mailutils.org/"
+SRC_URI="mirror://gnu/mailutils/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos"
+IUSE="berkdb bidi +clients emacs gdbm sasl guile ipv6 kerberos kyotocabinet \
+	ldap mysql nls pam postgres python servers split-usr ssl static-libs +threads tcpd \
+	tokyocabinet"
+
+RDEPEND="
+	!mail-filter/libsieve
+	!mail-client/mailx
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+	dev-libs/libltdl:0
+	virtual/libcrypt:=
+	virtual/mta
+	berkdb? ( sys-libs/db:= )
+	bidi? ( dev-libs/fribidi )
+	emacs? ( >=app-editors/emacs-23.1:* )
+	gdbm? ( sys-libs/gdbm:= )
+	guile? ( dev-scheme/guile:12/2.2-1 )
+	kerberos? ( virtual/krb5 )
+	kyotocabinet? ( dev-db/kyotocabinet )
+	ldap? ( net-nds/openldap )
+	mysql? ( dev-db/mysql-connector-c )
+	nls? ( sys-devel/gettext )
+	pam? ( sys-libs/pam:= )
+	postgres? ( dev-db/postgresql:= )
+	python? ( ${PYTHON_DEPS} )
+	sasl? ( virtual/gsasl )
+	servers? ( virtual/libiconv dev-libs/libunistring:= )
+	ssl? ( net-libs/gnutls:= )
+	tcpd? ( sys-apps/tcp-wrappers )
+	tokyocabinet? ( dev-db/tokyocabinet )
+	"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	servers? ( tcpd ldap )"
+
+DOCS=( ABOUT-NLS AUTHORS COPYING COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO )
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.5-add-include.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	if use mysql; then
+		sed -i -e /^INCLUDES/"s:$:$(mysql_config --include):" \
+			sql/Makefile.am || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	# maildir is the Gentoo default
+	econf \
+		MU_DEFAULT_SCHEME=maildir \
+		CURSES_LIBS="$($(tc-getPKG_CONFIG) --libs ncurses)" \
+		$(use_with berkdb berkeley-db) \
+		$(use_with bidi fribidi) \
+		$(use_enable ipv6) \
+		$(use_with gdbm) \
+		$(use_with sasl gsasl) \
+		$(use_with guile) \
+		$(use_with kerberos gssapi) \
+		$(use_with ldap) \
+		$(use_with mysql) \
+		$(use_enable nls) \
+		$(use_enable pam) \
+		$(use_with postgres) \
+		$(use_enable python) \
+		$(use_with ssl gnutls) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with tokyocabinet) \
+		$(use_with kyotocabinet) \
+		$(use_with tcpd tcp-wrappers) \
+		$(use_enable servers build-servers) \
+		$(use_with servers unistring ) \
+		$(use_enable clients build-clients) \
+		EMACS=$(usex emacs emacs no) \
+		--with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		--with-mail-spool=/var/spool/mail \
+		--with-readline \
+		--enable-sendmail \
+		--disable-debug
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	# bug 613112
+	newins "${FILESDIR}/mailutils.rc" mailutils.conf
+	keepdir /etc/mailutils.d/
+	insinto /etc/mailutils.d
+	doins "${FILESDIR}/mail"
+
+	if use python; then
+		python_optimize
+		if use static-libs; then
+			rm -r "${D}$(python_get_sitedir)/mailutils"/*.{a,la} || die
+		fi
+	fi
+
+	if use servers; then
+		newinitd "${FILESDIR}"/imap4d.initd imap4d
+		newinitd "${FILESDIR}"/pop3d.initd pop3d
+		newinitd "${FILESDIR}"/comsatd.initd comsatd
+	fi
+
+	# compatibility link
+	if use clients && use split-usr; then
+		dosym ../usr/bin/mail /bin/mail
+	fi
+
+	if ! use static-libs; then
+		find "${D}" -name "*.la" -delete || die
+	fi
+}