[gentoo-commits] repo/gentoo:master commit in: media-libs/libzmf/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     59ec5e0556b3c9df5d552fa9b68e9dca268e97c3
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  3 13:36:19 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Aug  3 14:06:39 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=59ec5e05

media-libs/libzmf: EAPI-8 bump, https, consolidate live/release ifdefs

Bug: https://bugs.gentoo.org/787266
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-libs/libzmf/libzmf-9999.ebuild | 36 ++++++++++++++++++++----------------
 1 file changed, 20 insertions(+), 16 deletions(-)

diff --git a/media-libs/libzmf/libzmf-9999.ebuild b/media-libs/libzmf/libzmf-9999.ebuild
index f58ce3535bd..5979e0f4894 100644
--- a/media-libs/libzmf/libzmf-9999.ebuild
+++ b/media-libs/libzmf/libzmf-9999.ebuild
@@ -1,21 +1,23 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
-EGIT_REPO_URI="git://gerrit.libreoffice.org/libzmf"
-[[ ${PV} == 9999 ]] && inherit git-r3 autotools
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.libreoffice.org/libzmf"
+	inherit git-r3 autotools
+else
+	SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
 
 DESCRIPTION="Library for parsing Zoner Callisto/Draw documents"
 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libzmf"
-[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-
 IUSE="debug doc test tools"
+
 RESTRICT="!test? ( test )"
 
 RDEPEND="
@@ -26,25 +28,27 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}
 	dev-libs/boost
-	doc? ( app-doc/doxygen )
 	test? ( dev-util/cppunit )
 "
+BDEPEND="doc? ( app-doc/doxygen )"
 
 src_prepare() {
 	default
-	[[ ${PV} == 9999 ]] && eautoreconf
+	[[ ${PV} == *9999* ]] && eautoreconf
 }
 
 src_configure() {
-	econf \
-		--disable-werror \
-		$(use_enable debug) \
-		$(use_with doc docs) \
-		$(use_enable test tests) \
+	local myeconfargs=(
+		--disable-werror
+		$(use_enable debug)
+		$(use_with doc docs)
+		$(use_enable test tests)
 		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
 	default
-	find "${D}" -name '*.la' -delete || die
+	find "${ED}" -name '*.la' -delete || die
 }