[gentoo-commits] repo/gentoo:master commit in: x11-libs/xapps/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     f1a64e7a0ec8d7594b3284b5417ec1f17ec12bb0
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Sat Jul 24 20:14:03 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sat Jul 31 08:35:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1a64e7a

x11-libs/xapps: 2.2.3 version bump

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 x11-libs/xapps/Manifest           |  1 +
 x11-libs/xapps/xapps-2.2.3.ebuild | 93 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/x11-libs/xapps/Manifest b/x11-libs/xapps/Manifest
index 87cf97e69f0..5944b6c9814 100644
--- a/x11-libs/xapps/Manifest
+++ b/x11-libs/xapps/Manifest
@@ -1,2 +1,3 @@
 DIST xapps-2.2.1.tar.gz 239789 BLAKE2B ee7f3f2b3c54b0b40158dff6abbe2233c0d1a1fa4e134ce4bd6ee48842335b16e0d94ad430cb59301529dd85e2705cbb1c1f5ba10844b6fb85f598ca0c42d1db SHA512 412f5c207d81d2507f2aa5cc69beed2036db07058f08613793aa7c277bac30191a02d9aff4eca0aeb8829e3e39d5f3a87e34232bf51220c4d4bc7c8ee37b9e65
 DIST xapps-2.2.2.tar.gz 239823 BLAKE2B a45b2707c505c9ed69b9748c846f69ef7668600619bc3d0f86c693c99e536afb9994ff4ed10cbf0efc194a1e861cf0911af50170e97a7b858b1363c370551799 SHA512 ab37714849365a81b2a500ed38ada9bf6b52edc17d3b3bfa6d41551a18af1b983f8fe084dee94939e81647814a77d2c219b87694349ac5d0d0ac59ba5ad79aa7
+DIST xapps-2.2.3.tar.gz 242330 BLAKE2B dba7f77eea7314fe978a1ba2b691f5c2d7e5d88f499d2f8533c8b1141262ce981cc395f8d6a0b1feaba715c63034e8dfe887e4183b5e119a0947b1ad85d99bbd SHA512 e8ac24decfa89aa949cf837a2e7a7ccdb8ef9d777081d0f3ea0e3a0b42378c721eed3eafacae669244a64c7f4202cb5c2a878d3574823f8f94bfdf51ec29f9ae

diff --git a/x11-libs/xapps/xapps-2.2.3.ebuild b/x11-libs/xapps/xapps-2.2.3.ebuild
new file mode 100644
index 00000000000..a7434062a55
--- /dev/null
+++ b/x11-libs/xapps/xapps-2.2.3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2-utils vala meson python-r1 xdg-utils
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+LICENSE="GPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/xapp-${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.44.0:2
+	dev-libs/gobject-introspection:0=
+	dev-libs/libdbusmenu[gtk3]
+	gnome-base/libgnomekbd
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.16.0:3[introspection?]
+	x11-libs/libxkbfile
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40.6
+	sys-devel/gettext
+
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	vala_src_prepare
+	default
+
+	# don't install distro specific tools
+	sed -i "/subdir('scripts')/d" meson.build || die
+
+	# Fix meson helpers
+	python_setup
+	python_fix_shebang meson-scripts
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${EPYTHON}" -c 'import gi;print(gi._overridesdir)' || die)
+		einfo "gobject overrides directory: ${PYTHON_GI_OVERRIDESDIR}"
+		mkdir -p "${D}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		cp -r "${D}"/pygobject/* "${D}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		python_optimize "${D}/${PYTHON_GI_OVERRIDESDIR}/"
+	}
+	python_foreach_impl install_pygobject_override
+	rm -r "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}