[gentoo-commits] repo/gentoo:master commit in: net-analyzer/nagios-check_multiple/

["Michael Orlitzky" <mjo@gentoo.org>]

commit:     8b9340b3fcd6e81ce638f398effda3ad4be61436
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 29 23:25:41 2021 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Thu Jul 29 23:25:41 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b9340b3

net-analyzer/nagios-check_multiple: revision for python-3.{9,10}.

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Michael Orlitzky <mjo <AT> gentoo.org>

 .../nagios-check_multiple-0.0.1-r1.ebuild          | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/net-analyzer/nagios-check_multiple/nagios-check_multiple-0.0.1-r1.ebuild b/net-analyzer/nagios-check_multiple/nagios-check_multiple-0.0.1-r1.ebuild
new file mode 100644
index 00000000000..2dd65336bb2
--- /dev/null
+++ b/net-analyzer/nagios-check_multiple/nagios-check_multiple-0.0.1-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_7,3_8,3_9,3_10} )
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1
+
+MY_PN="check_multiple"
+DESCRIPTION="A Nagios plugin to execute multiple checks in parallel"
+HOMEPAGE="https://github.com/clarkbox/check_multiple"
+SRC_URI="https://github.com/clarkbox/check_multiple/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_install() {
+	distutils-r1_src_install
+
+	local nagiosplugindir="/usr/$(get_libdir)/nagios/plugins"
+	dodir "${nagiosplugindir}"
+
+	# Create a symlink from the nagios plugin directory to the /usr/bin
+	# location. The "binary" in /usr/bin should also be a symlink, since
+	# the python machinery allows the user to switch out the
+	# interpreter. We don't want to mess with any of that, so we just
+	# point to whatever the system would use if the user executed
+	# ${MY_PN}.
+	#
+	# The relative symlink is preferred so that if the package is
+	# installed e.g. while in a chroot, the symlink will never point
+	# outside of that chroot.
+	#
+	dosym "../../../bin/${MY_PN}" "${nagiosplugindir}/${MY_PN}"
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest -v lib/check_multiple/check_multiple.py \
+		|| die "test suite failed"
+}