[gentoo-commits] repo/gentoo:master commit in: www-servers/h2o/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     c409b27799e4d50b493c5b57f68f30b04cadcbad
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 23 20:33:29 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Jul 23 20:37:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c409b277

www-servers/h2o: drop old version

Closes: https://bugs.gentoo.org/781539
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 www-servers/h2o/h2o-2.2.6.ebuild | 107 ---------------------------------------
 1 file changed, 107 deletions(-)

diff --git a/www-servers/h2o/h2o-2.2.6.ebuild b/www-servers/h2o/h2o-2.2.6.ebuild
deleted file mode 100644
index 41caa3e517e..00000000000
--- a/www-servers/h2o/h2o-2.2.6.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-CMAKE_MAKEFILE_GENERATOR="emake"
-SSL_DEPS_SKIP=1
-USE_RUBY="ruby24 ruby25 ruby26"
-
-inherit cmake-utils ruby-single ssl-cert systemd toolchain-funcs user
-
-DESCRIPTION="H2O - the optimized HTTP/1, HTTP/2 server"
-HOMEPAGE="https://h2o.examp1e.net/"
-SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="libh2o +mruby"
-
-RDEPEND="dev-lang/perl
-	sys-libs/zlib
-	libh2o? ( dev-libs/libuv )
-	dev-libs/openssl:0=
-	"
-DEPEND="${RDEPEND}
-	libh2o? ( virtual/pkgconfig )
-	mruby? (
-		${RUBY_DEPS}
-		|| (
-			dev-libs/onigmo
-			dev-libs/oniguruma
-		)
-		sys-devel/bison
-		virtual/pkgconfig
-	)"
-RDEPEND+="
-	!sci-libs/libh2o"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.2-mruby.patch
-)
-
-pkg_setup() {
-	enewgroup ${PN}
-	enewuser ${PN} -1 -1 -1 ${PN}
-}
-
-src_prepare() {
-	cmake-utils_src_prepare
-
-	local ruby="ruby"
-	if use mruby; then
-		for ruby in ${RUBY_TARGETS_PREFERENCE}; do
-			if has_version dev-lang/ruby:${ruby:4:1}.${ruby:5}; then
-				break
-			fi
-			ruby=
-		done
-		[[ -z ${ruby} ]] && die "no suitable ruby version found"
-	fi
-
-	sed -i \
-		-e "/INSTALL/s:\(/doc/${PN}\) :\1/html :" \
-		-e "/INSTALL/s:\(/doc\)/${PN}:\1/${PF}:" \
-		-e "s: ruby: ${ruby}:" \
-		CMakeLists.txt
-
-	sed -i "s:pkg-config:$(tc-getPKG_CONFIG):g" deps/mruby/lib/mruby/gem.rb
-	tc-export CC
-	export LD="$(tc-getCC)"
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc/${PN}
-		-DWITH_MRUBY=$(usex mruby)
-		-DWITHOUT_LIBS=$(usex !libh2o)
-		-DBUILD_SHARED_LIBS=$(usex libh2o)
-	)
-	cmake-utils_src_configure
-}
-
-src_install() {
-	cmake-utils_src_install
-
-	keepdir /var/www/localhost/htdocs
-
-	insinto /etc/${PN}
-	doins "${FILESDIR}"/${PN}.conf
-
-	newinitd "${FILESDIR}"/${PN}.initd ${PN}
-	systemd_dounit "${FILESDIR}"/${PN}.service
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}"/${PN}.logrotate ${PN}
-
-	keepdir /var/log/${PN}
-	fowners ${PN}:${PN} /var/log/${PN}
-	fperms 0750 /var/log/${PN}
-}
-
-pkg_postinst() {
-	if [[ ! -f "${EROOT}"etc/ssl/${PN}/server.key ]]; then
-		install_cert /etc/ssl/${PN}/server
-		chown ${PN}:${PN} "${EROOT}"etc/ssl/${PN}/server.*
-	fi
-}