[gentoo-commits] repo/gentoo:master commit in: dev-libs/folks/

["Matt Turner" <mattst88@gentoo.org>]

commit:     426e4d05d54fddf097080ebc3f4981464cd7f21b
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 23 02:31:33 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Jul 23 04:26:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=426e4d05

dev-libs/folks: Version bump to 0.15.3

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/folks/Manifest            |  1 +
 dev-libs/folks/folks-0.15.3.ebuild | 92 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 93 insertions(+)

diff --git a/dev-libs/folks/Manifest b/dev-libs/folks/Manifest
index 31522029d2e..92520eacfbf 100644
--- a/dev-libs/folks/Manifest
+++ b/dev-libs/folks/Manifest
@@ -1 +1,2 @@
 DIST folks-0.15.2.tar.xz 489236 BLAKE2B 63bcfedb88205b37c6e9595c3e0c34f7fc869045648e04042cce9300776e4b7d102f91312434545581882f0959502be7ba1bc2f77d50ec2af7f649444da9197d SHA512 c327e39b7cf32b72db3f84504f8ec2a4bc2d98693ca5ff21c3b544e37b58a1df9241dd1be541a39be83468b62dd0f5d7b5a3a0ca4bde5e94d1e075d77d3be505
+DIST folks-0.15.3.tar.xz 491432 BLAKE2B f11123a2c41c4a36c002b26f3c3616d62e4a74bbddbde84643143404497c8e3c31d8cafc8bff0ba4714606259aaa6f7adf352ba4bb98a20c75a181ee68bfda3a SHA512 dd54aef470990974bfc9b22fb83c868ca9674608ccfddeea1bb7507dfc77d7d12a43d43462957b0bb99bf249c13868ba7326f7fd7e38de8802a3ba54e33d8d58

diff --git a/dev-libs/folks/folks-0.15.3.ebuild b/dev-libs/folks/folks-0.15.3.ebuild
new file mode 100644
index 00000000000..dce27502ec3
--- /dev/null
+++ b/dev-libs/folks/folks-0.15.3.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.48"
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Library for aggregating people from multiple sources"
+HOMEPAGE="https://wiki.gnome.org/Projects/Folks https://gitlab.gnome.org/GNOME/folks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/26" # subslot = libfolks soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+
+IUSE="bluetooth eds +telepathy test utils"
+REQUIRED_USE="bluetooth? ( eds )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.58:2
+	>=dev-libs/libgee-0.10:0.8[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	telepathy? (
+		>=net-libs/telepathy-glib-0.19.9
+		dev-libs/dbus-glib
+	)
+	eds? ( >=gnome-extra/evolution-data-server-3.38:= )
+	dev-libs/libxml2:2
+	utils? ( sys-libs/readline:0= )
+"
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${DEPEND}
+	bluetooth? ( >=net-wireless/bluez-5[obex] )
+	telepathy? ( net-im/telepathy-mission-control )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	telepathy? ( net-libs/telepathy-glib[vala] )
+	eds? ( gnome-extra/evolution-data-server[vala] )
+	test? (
+		sys-apps/dbus
+		bluetooth? ( $(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]') )
+	)
+"
+
+python_check_deps() {
+	if use test && use bluetooth; then
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth bluez_backend)
+		$(meson_use eds eds_backend)
+		$(meson_use eds ofono_backend)
+		$(meson_use telepathy telepathy_backend)
+		-Dzeitgeist=false # last rited package
+		-Dimport_tool=true
+		$(meson_use utils inspect_tool)
+		$(meson_use test tests)
+		-Dinstalled_tests=false
+		-Ddocs=false # Needs find_program sedding to specific version; only dev docs, don't bother
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" -t 5
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}