[gentoo-commits] repo/gentoo:master commit in: dev-libs/imath/

["Marek Szuba" <marecki@gentoo.org>]

commit:     e863ec680789e76c432a07f1ed614b79b9d300fa
Author:     Bernd Waibel <waebbl-gentoo <AT> posteo <DOT> net>
AuthorDate: Tue Jul 20 16:41:21 2021 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Wed Jul 21 21:57:27 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e863ec68

dev-libs/imath: drop 3.0.1

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Bernd Waibel <waebbl-gentoo <AT> posteo.net>
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 dev-libs/imath/Manifest           |  1 -
 dev-libs/imath/imath-3.0.1.ebuild | 90 ---------------------------------------
 2 files changed, 91 deletions(-)

diff --git a/dev-libs/imath/Manifest b/dev-libs/imath/Manifest
index 29ce5f6f448..1cdecf3c54b 100644
--- a/dev-libs/imath/Manifest
+++ b/dev-libs/imath/Manifest
@@ -1,2 +1 @@
-DIST imath-3.0.1.tar.gz 527715 BLAKE2B 45d8f6524fd2505bdb3318f571c44228c9baf6df869d194d4b90a9c045f1dbb8f905253aeaf6b6a9254e4b0c0c19d753b7e4ae068732f0367fc936d4a111520d SHA512 40cdae81d624636b3dd7eb456e6e205e5b7adf7aed17f6e9168374f8830f1b5755dcd32ac790f94e768513d06ab96d94a2bc57ec80a079e4ac94a3857e5e3988
 DIST imath-3.0.5.tar.gz 528503 BLAKE2B c1fcb199a81aff25f1ad26ccfcef2802861401f3fee5dc24035216aa16fd9a5344ec6c37139a0850f1a4bc580dc1fdd068eca9473a19e4aaf329cfc5f53a4cd6 SHA512 df206315d822266cf32a5a4399abff7ad1dd0bd1f0372d61f61516e2acdefd13e3cfd9cf54373a3fb49bb28c9f80915ca5ecaec2a068a1d6ea231d71a5316da2

diff --git a/dev-libs/imath/imath-3.0.1.ebuild b/dev-libs/imath/imath-3.0.1.ebuild
deleted file mode 100644
index 47ac92fa5ce..00000000000
--- a/dev-libs/imath/imath-3.0.1.ebuild
+++ /dev/null
@@ -1,90 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8,9} )
-
-inherit cmake python-single-r1
-
-MY_PN=Imath
-
-DESCRIPTION="Imath basic math package"
-HOMEPAGE="https://imath.readthedocs.io"
-SRC_URI="https://github.com/AcademySoftwareFoundation/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-# re-keywording needed for (according to ilmbase keywords):
-# ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x64-macos ~x86-solaris
-KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
-S="${WORKDIR}/${MY_PN}-${PV}"
-
-LICENSE="BSD"
-SLOT="0/27"
-IUSE="doc large-stack python static-libs test"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-RESTRICT="!test? ( test )"
-
-# libImath.so conflicts with ilmbase
-RDEPEND="
-	!media-libs/ilmbase
-	sys-libs/zlib
-	python? (
-		!dev-python/pyilmbase
-		${PYTHON_DEPS}
-		$(python_gen_cond_dep '
-			dev-libs/boost:=[python?,${PYTHON_USEDEP}]
-			dev-python/numpy[${PYTHON_USEDEP}]
-		')
-	)
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	doc? ( $(python_gen_cond_dep 'dev-python/breathe[${PYTHON_USEDEP}]') )
-	python? ( ${PYTHON_DEPS} )
-"
-
-DOCS=( CHANGES.md CONTRIBUTORS.md README.md SECURITY.md docs/PortingGuide2-3.md )
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_SHARED_LIBS=$(usex !static-libs)
-		-DIMATH_ENABLE_LARGE_STACK=$(usex large-stack)
-		-DIMATH_INSTALL_PKG_CONFIG=ON
-		-DIMATH_USE_CLANG_TIDY=OFF
-	)
-
-	if use python; then
-		mycmakeargs+=(
-			-DPYTHON=ON
-			-DPython3_EXECUTABLE="${PYTHON}"
-			-DPython3_INCLUDE_DIR=$(python_get_includedir)
-			-DPython3_LIBRARY=$(python_get_library_path)
-		)
-	fi
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-
-	if use doc; then
-		pushd "${S}"/docs 2>/dev/null || die
-		doxygen || die
-		emake html
-		popd 2>/dev/null || die
-	fi
-}
-
-src_install() {
-	cmake_src_install
-
-	if use doc; then
-		HTML_DOCS=( "${S}/docs/_build/html/." )
-		einstalldocs
-	fi
-}