[gentoo-commits] repo/gentoo:master commit in: media-sound/rplay/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     53e8ed66412695fd96bc0838b8d0a4488e11f1f7
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 13 19:29:31 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Tue Jul 13 20:55:09 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53e8ed66

media-sound/rplay: migrate to GLEP 81

Bug: https://bugs.gentoo.org/781335
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 media-sound/rplay/rplay-3.3.2-r4.ebuild | 57 +++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/media-sound/rplay/rplay-3.3.2-r4.ebuild b/media-sound/rplay/rplay-3.3.2-r4.ebuild
new file mode 100644
index 00000000000..0cbf1cbc4a6
--- /dev/null
+++ b/media-sound/rplay/rplay-3.3.2-r4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Play sounds on remote Unix systems without data transfer"
+HOMEPAGE="http://rplay.doit.org/"
+SRC_URI="
+	http://rplay.doit.org/dist/${P}.tar.gz
+	mirror://debian/pool/main/r/${PN}/${PN}_${PV}-16.debian.tar.xz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ppc ppc64 ~s390 sparc x86"
+
+RDEPEND="
+	acct-group/rplayd
+	acct-user/rplayd
+	media-sound/gsm
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${WORKDIR}/debian/patches"
+	"${FILESDIR}/${P}-built-in_function_exit-r1.patch"
+)
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	mv rx/configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-rplayd-user=rplayd \
+		--enable-rplayd-group=rplayd
+}
+
+src_install() {
+	# This is borrowed from the old einstall helper, and is necessary
+	# (at least some of variables).
+	emake prefix="${ED}/usr" \
+		libdir="${ED}/usr/$(get_libdir)" \
+		datadir="${ED}/usr/share" \
+		infodir="${ED}/usr/share/info" \
+		localstatedir="${ED}/var/lib" \
+		mandir="${ED}/usr/share/man" \
+		sysconfdir="${ED}/etc" \
+		install
+
+	find "${ED}" -name '*.la' -delete || die
+}