[gentoo-commits] repo/gentoo:master commit in: mail-filter/mimedefang/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     41637206b025f07ce17210d14b9895a6207b3abd
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 11 20:46:16 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Jul 11 21:18:22 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41637206

mail-filter/mimedefang: migrate to GLEP 81

Bug: https://bugs.gentoo.org/781308
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 mail-filter/mimedefang/mimedefang-2.84-r1.ebuild | 78 ++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/mail-filter/mimedefang/mimedefang-2.84-r1.ebuild b/mail-filter/mimedefang/mimedefang-2.84-r1.ebuild
new file mode 100644
index 00000000000..e916663dfa6
--- /dev/null
+++ b/mail-filter/mimedefang/mimedefang-2.84-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Antispam, antivirus and other customizable filters for MTAs with Milter support"
+HOMEPAGE="http://www.mimedefang.org/"
+SRC_URI="http://www.mimedefang.org/static/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clamav +poll test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/defang
+	acct-user/defang
+	dev-perl/Digest-SHA1
+	dev-perl/IO-stringy
+	dev-perl/MailTools
+	dev-perl/MIME-tools
+	dev-perl/Unix-Syslog
+	|| ( mail-filter/libmilter mail-mta/sendmail )
+	virtual/perl-MIME-Base64
+	clamav? ( app-antivirus/clamav )
+"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-perl/Test-Class
+		dev-perl/Test-Most
+	)
+"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-2.72-ldflags.patch"
+	eapply "${FILESDIR}/${PN}-tests.patch"
+	eapply_user
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-user=defang
+		$(use_enable poll)
+		$(use_enable clamav)
+		$(use_enable clamav clamd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" INSTALL_STRIP_FLAG="" install
+
+	fowners defang:defang /etc/mail/mimedefang-filter
+	fperms 644 /etc/mail/mimedefang-filter
+	insinto /etc/mail/
+	newins "${S}"/SpamAssassin/spamassassin.cf sa-mimedefang.cf
+
+	keepdir /var/spool/{MD-Quarantine,MIMEDefang}
+	fowners defang:defang /var/spool/{MD-Quarantine,MIMEDefang}
+	fperms 700 /var/spool/{MD-Quarantine,MIMEDefang}
+
+	keepdir /var/log/mimedefang
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+
+	dodoc -r examples contrib
+}
+
+pkg_postinst() {
+	elog "You can install Mail::SpamAssassin (mail-filter/spamassassin) and"
+	elog "HTML::Parser (dev-perl/HTML-Parser) even after installing if you require"
+	elog "them as they are loaded at run-time."
+}