[gentoo-commits] repo/gentoo:master commit in: app-accessibility/espeak-ng/

["William Hubbs" <williamh@gentoo.org>]

commit:     d9f06ef14e0da05bf7a6fbd2071aa1d20ea9aadf
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Wed Jul  7 17:06:51 2021 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Wed Jul  7 17:10:02 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9f06ef1

app-accessibility/espeak-ng: add live ebuild

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 app-accessibility/espeak-ng/espeak-ng-9999.ebuild | 82 +++++++++++++++++++++++
 1 file changed, 82 insertions(+)

diff --git a/app-accessibility/espeak-ng/espeak-ng-9999.ebuild b/app-accessibility/espeak-ng/espeak-ng-9999.ebuild
new file mode 100644
index 00000000000..941edd1d327
--- /dev/null
+++ b/app-accessibility/espeak-ng/espeak-ng-9999.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Software speech synthesizer for English, and some other languages"
+HOMEPAGE="https://github.com/espeak-ng/espeak-ng"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/espeak-ng/espeak-ng.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/espeak-ng/espeak-ng/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+ Turkowski unicode"
+SLOT="0"
+IUSE="+async +klatt l10n_ru l10n_zh man mbrola +sound"
+
+COMMON_DEPEND="
+	!app-accessibility/espeak
+	mbrola? ( app-accessibility/mbrola )
+	sound? ( media-libs/pcaudiolib )
+"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}
+	sound? ( media-sound/sox )
+"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( app-text/ronn )
+"
+
+DOCS=( CHANGELOG.md README.md docs )
+
+src_prepare() {
+	default
+
+	# disable failing tests
+	rm tests/{language-pronunciation,translate}.test || die
+	sed -i \
+		-e "/language-pronunciation.check/d" \
+		-e "/translate.check/d" \
+		Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local econf_args
+	econf_args=(
+		$(use_with async)
+		$(use_with klatt)
+		$(use_with l10n_ru extdict-ru)
+		$(use_with l10n_zh extdict-cmn)
+		$(use_with l10n_zh extdict-yue)
+		$(use_with mbrola)
+		$(use_with sound pcaudiolib)
+		--without-libfuzzer
+		--without-sonic
+		--disable-rpath
+		--disable-static
+	)
+	econf "${econf_args[@]}"
+}
+
+src_compile() {
+	# see docs/building.md
+	emake -j1
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	emake DESTDIR="${D}" VIMDIR=/usr/share/vimfiles install
+	rm "${ED}"/usr/lib*/*.la || die
+}