[gentoo-commits] repo/gentoo:master commit in: app-vim/command-t/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     c08b3736776549d2a78a50b6372066e0f7a0d19c
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Tue Jul  6 08:37:10 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Tue Jul  6 08:37:36 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c08b3736

app-vim/command-t: add ruby27, ruby30; EAPI 7

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 app-vim/command-t/command-t-5.0.3-r1.ebuild | 47 +++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/app-vim/command-t/command-t-5.0.3-r1.ebuild b/app-vim/command-t/command-t-5.0.3-r1.ebuild
new file mode 100644
index 00000000000..88a26579c20
--- /dev/null
+++ b/app-vim/command-t/command-t-5.0.3-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27 ruby30"
+
+inherit vim-plugin ruby-ng
+
+DESCRIPTION="vim plugin: fast file navigation for vim"
+HOMEPAGE="https://vim.sourceforge.io/scripts/script.php?script_id=3025 https://github.com/wincent/command-t"
+SRC_URI="https://github.com/wincent/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD-2"
+KEYWORDS="~amd64 ~x86"
+
+VIM_PLUGIN_HELPFILES="${PN}.txt"
+
+RDEPEND="|| ( app-editors/vim[ruby] app-editors/gvim[ruby] )"
+
+all_ruby_prepare() {
+	find "${S}" -name .gitignore -delete || die
+}
+
+each_ruby_configure() {
+	cd ruby/${PN}/ext/${PN} || die
+	${RUBY} extconf.rb || die "extconf.rb failed"
+}
+
+each_ruby_compile() {
+	cd ruby/${PN}/ext/${PN} || die
+	emake V=1
+	rm *.o *.c *.h *.log extconf.rb depend Makefile || die
+}
+
+each_ruby_install() {
+	local sitelibdir=$(ruby_rbconfig_value "sitelibdir")
+	insinto "${sitelibdir}"
+	doins -r ruby/${PN}/{ext,lib}/*
+}
+
+all_ruby_install() {
+	rm -r appstream bin fixtures data ruby/${PN}/{ext,lib,*.gemspec} spec vendor || die
+
+	vim-plugin_src_install
+
+	# make sure scripts are executable
+	chmod +x "${ED}"/usr/share/vim/vimfiles/ruby/${PN}/bin/* || die
+}