[gentoo-commits] repo/gentoo:master commit in: dev-python/graph-tool/

["David Seifert" <soap@gentoo.org>]

commit:     f6e240c4d69810664bdcb8f67135abfd83c617e6
Author:     Gerion Entrup <gerion.entrup <AT> flump <DOT> de>
AuthorDate: Sun Jul  4 14:03:56 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Jul  4 14:03:56 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f6e240c4

dev-python/graph-tool: bump to 2.41

Closes: https://github.com/gentoo/gentoo/pull/21454
Closes: https://bugs.gentoo.org/795603
Signed-off-by: Gerion Entrup <gerion.entrup <AT> flump.de>
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 dev-python/graph-tool/Manifest               |  1 +
 dev-python/graph-tool/graph-tool-2.41.ebuild | 84 ++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index be2792d394a..802c47de23a 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1 +1,2 @@
 DIST graph-tool-2.35.tar.bz2 15153787 BLAKE2B 31f815f564510bb9628f43e8afab1a561222d23aabc3417ce474f0db69625954fc46119f61e8d7764d49a291e16e3b32f2e4249304f934c08d17af3e47a39ce8 SHA512 eadb122b75ff95fde165bfe1be8387deb08b48d041236aff11a0b8414d1a5027931a5e4b3216348edb61c53187b191a5e78af4eabb1ce679dd8736651f142bec
+DIST graph-tool-2.41.tar.bz2 15171880 BLAKE2B 5d520e8676ebc8a363ab80d784bfdcc6746807a31dca6d3b1f27cdc1c865d60ba6e6fa64c3dc91e69dd7b2b07f56242facd435c89b0e1058f7d302e04f3144f9 SHA512 c1f71292d9db6977c20e8a6945dedefbe623070f08d62e3427ee11c5a936995ceb48f62ab7638ba6732b2436f762776d8acbc20a6b60e3cefe3ba298ab5ef0c5

diff --git a/dev-python/graph-tool/graph-tool-2.41.ebuild b/dev-python/graph-tool/graph-tool-2.41.ebuild
new file mode 100644
index 00000000000..cf2e5589ad5
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.41.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/boost-1.70:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	# most machines don't have enough ram for parallel builds
+	python_foreach_impl run_in_build_dir emake -j2
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}