From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1298758-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id B1D6D13933E
	for <garchives@archives.gentoo.org>; Sat,  3 Jul 2021 08:16:37 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 08CADE0801;
	Sat,  3 Jul 2021 08:16:37 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 4FF1EE0801
	for <gentoo-commits@lists.gentoo.org>; Sat,  3 Jul 2021 08:16:36 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id A2A70335D2F
	for <gentoo-commits@lists.gentoo.org>; Sat,  3 Jul 2021 08:16:34 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 380557C1
	for <gentoo-commits@lists.gentoo.org>; Sat,  3 Jul 2021 08:16:33 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1625300188.362fd3c89dc7ae56bfdc84fbda2faba9da43a0a1.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/pandas/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/pandas/Manifest dev-python/pandas/pandas-1.3.0.ebuild
X-VCS-Directories: dev-python/pandas/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 362fd3c89dc7ae56bfdc84fbda2faba9da43a0a1
X-VCS-Branch: master
Date: Sat,  3 Jul 2021 08:16:33 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 167955e6-a25c-4bfc-a271-5a9f24822a62
X-Archives-Hash: 43fb14a464ca1310d6b19774ee4105c3

commit:     362fd3c89dc7ae56bfdc84fbda2faba9da43a0a1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  3 06:43:39 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul  3 08:16:28 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=362fd3c8

dev-python/pandas: Bump to 1.3.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pandas/Manifest            |   1 +
 dev-python/pandas/pandas-1.3.0.ebuild | 192 ++++++++++++++++++++++++++++++++++
 2 files changed, 193 insertions(+)

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 8b790820335..4d334a762ed 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1,3 +1,4 @@
 DIST pandas-1.2.3.tar.gz 5466356 BLAKE2B f392321915128769814b3a8b7673cd7b00c9c292f4cb8d8b2e8537f7cc513f92cb6b8ff74dffe3b167987e8fa387738264dbebfdf4019f9cd7afd4f78234212a SHA512 3108424253aa143a85ef166091829bbd8c9b6446b516f37252742146d184f722e1fb8af5b4d04937362a298068019a91392e40c818126df6a7459bab7f3077cb
 DIST pandas-1.2.4.tar.gz 5469105 BLAKE2B 7f39e3ca67f5997c0668b0c2e9792869963adcd0347a3983188a992794ad58ccba82105b4dc3315cc17d79104f7fea7a273c218967eb51b1ea1514e87aeebb66 SHA512 79e7a38b8edad52b70eb81ba821141b928c782009d59c50076e7d1e7c015078d333c0c80bda7ba720f4ccb221a0ba93a02885fe6a573567ee37ffae14ee9b2c3
 DIST pandas-1.2.5.tar.gz 5470907 BLAKE2B 2c5e0cb0849aa23ee8640528a3e29a579cc051543731e44c9be41fb989c85f1b2b18bc028e97c9b200f9894e4c3ac8af6a2100586e41f6d8a165a4c4679fd649 SHA512 c8bc2ca7ff8ca1a4877ccda67aaf49c103525d0f511636f93e1db3720d9a1717aacde0a5e3f107f8f620b59f0269d9e5c9515fbef46da4e87fca678d7acda990
+DIST pandas-1.3.0.tar.gz 4721119 BLAKE2B f09eedd848686597a755da929683e841be61cce4385fa1e4616a328e267dcd4fb44bc9ad5da56402a52da6fb3b12f84795da10cd20df7fd0b349e749dd814bc3 SHA512 67145114091901d8e2a376392d8890372675a1b5831de310715a6e6f7f4509dd8cf1a4b30cab3314f849b6c709270a246524b958b686f9e7fbe2489ce5b650a0

diff --git a/dev-python/pandas/pandas-1.3.0.ebuild b/dev-python/pandas/pandas-1.3.0.ebuild
new file mode 100644
index 00000000000..bd75ba8b21c
--- /dev/null
+++ b/dev-python/pandas/pandas-1.3.0.ebuild
@@ -0,0 +1,192 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 flag-o-matic multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="https://pandas.pydata.org/ https://github.com/pandas-dev/pandas/"
+SRC_URI="
+	https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz"
+S="${WORKDIR}/${P/_/}"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.7.0[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+OPTIONAL_DEPEND="
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	|| (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	|| (
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	)
+	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.12.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+	X? (
+		|| (
+			dev-python/PyQt5[${PYTHON_USEDEP}]
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>=dev-python/numpy-1.17.3[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.1-r3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2017.3[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-python/cython-0.29.21[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/xlrd[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="${COMMON_DEPEND}
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	# requires package installed
+	sed -e '/extra_compile_args =/s:"-Werror"::' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+	fi
+}
+
+python_test() {
+	local deselect=(
+		# test for rounding errors, fails if we have better precision
+		# e.g. on amd64 with FMA or on arm64
+		# https://github.com/pandas-dev/pandas/issues/38921
+		pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+		# weird issue, doesn't seem very important
+		'pandas/tests/base/test_misc.py::test_memory_usage[series-with-empty-index]'
+
+		# old psycopg2 API
+		pandas/tests/tools/test_to_datetime.py::TestToDatetime::test_to_datetime_tz_psycopg2
+
+		# Internet
+		pandas/tests/io/xml/test_xml.py::test_wrong_url
+
+		# TODO: some data path problems?
+		pandas/tests/io/test_fsspec.py::test_read_csv
+		pandas/tests/io/test_fsspec.py::test_markdown_options
+	)
+
+	local -x LC_ALL=C.UTF-8
+	pushd "${BUILD_DIR}"/lib > /dev/null || die
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	PYTHONPATH=. virtx epytest pandas --skip-slow --skip-network \
+		${deselect[@]/#/--deselect } -m "not single" \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+	find . '(' -name .pytest_cache -o -name .hypothesis ')' \
+		-exec rm -r {} + || die
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.0" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-1.3.0"
+	optfeature "miscellaneous statistical functions" dev-python/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}