[gentoo-commits] repo/gentoo:master commit in: media-libs/liblrdf/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     745bebfc9d46884fc70fb1ae05fbcbf7d39fea0c
Author:     Haelwenn (lanodan) Monnier <contact <AT> hacktivis <DOT> me>
AuthorDate: Tue Jun 29 07:27:08 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Tue Jun 29 14:48:22 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=745bebfc

media-libs/liblrdf: make multilib

Required for >=media-plugins/gst-plugins-ladspa-1.18.4

Signed-off-by: Haelwenn (lanodan) Monnier <contact <AT> hacktivis.me>
Closes: https://github.com/gentoo/gentoo/pull/21468/commits/c2c36bef8009d850c2489ba9c7bac4e28aca8862
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-libs/liblrdf/liblrdf-0.6.1-r1.ebuild | 46 ++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/media-libs/liblrdf/liblrdf-0.6.1-r1.ebuild b/media-libs/liblrdf/liblrdf-0.6.1-r1.ebuild
new file mode 100644
index 00000000000..2c09c797bfe
--- /dev/null
+++ b/media-libs/liblrdf/liblrdf-0.6.1-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="Library for manipulation of RDF files in LADSPA plugins"
+HOMEPAGE="https://github.com/swh/LRDF"
+SRC_URI="https://github.com/swh/LRDF/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="static-libs"
+
+RDEPEND="
+	media-libs/ladspa-sdk[${MULTILIB_USEDEP}]
+	media-libs/raptor:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README )
+
+S="${WORKDIR}/LRDF-${PV}"
+
+src_prepare() {
+	default
+	sed -i -e 's:usr/local:usr:' examples/{instances,remove}_test.c || die #392221
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+multilib_src_test() {
+	has_version media-plugins/swh-plugins && default #392221
+}
+
+multilib_src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}