From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1296692-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id DEF38138956
for <garchives@archives.gentoo.org>; Fri, 25 Jun 2021 01:10:12 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id F1B0DE08A2;
Fri, 25 Jun 2021 01:10:11 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id BCEE9E08A2
for <gentoo-commits@lists.gentoo.org>; Fri, 25 Jun 2021 01:10:11 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A7F4C342A4F
for <gentoo-commits@lists.gentoo.org>; Fri, 25 Jun 2021 01:02:22 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 357A97AF
for <gentoo-commits@lists.gentoo.org>; Fri, 25 Jun 2021 01:02:21 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1624582926.9dcecf905a782155e2aeb827a7c70964d1c13622.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-crypt/gpgme/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-crypt/gpgme/Manifest app-crypt/gpgme/gpgme-1.16.0.ebuild
X-VCS-Directories: app-crypt/gpgme/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 9dcecf905a782155e2aeb827a7c70964d1c13622
X-VCS-Branch: master
Date: Fri, 25 Jun 2021 01:02:21 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: c6a5ef26-1340-44a8-914d-84b98f8b593a
X-Archives-Hash: da4f14b04a96421a01b96d6e588305f9
commit: 9dcecf905a782155e2aeb827a7c70964d1c13622
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 25 00:36:43 2021 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Jun 25 01:02:06 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9dcecf90
app-crypt/gpgme: Bump to version 1.16.0
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
app-crypt/gpgme/Manifest | 1 +
app-crypt/gpgme/gpgme-1.16.0.ebuild | 110 ++++++++++++++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/app-crypt/gpgme/Manifest b/app-crypt/gpgme/Manifest
index 48746098dd1..aacbbd833e9 100644
--- a/app-crypt/gpgme/Manifest
+++ b/app-crypt/gpgme/Manifest
@@ -1,3 +1,4 @@
DIST gpgme-1.14.0.tar.bz2 1678910 BLAKE2B 75051166b1f3777d630236c5afbd1786df238272b7ccfd053c5a4b2a207ba146550f6be46c1211f3bacbe19fee2f67adbc5be558d69175c19230a1a02e32d9f2 SHA512 b7ffa30a046c75215e1c73e2f34e5e65532e4dcf6bea55796adc6f82fd38dafe264bcd4332b2001155d6f9476d6fd82a77112dad31c1bb29db9ddefc532ae668
DIST gpgme-1.15.0.tar.bz2 1692019 BLAKE2B 4c66f24034a88e7da8a06cef3d0ac9d1d6b5eccb6d4277d36a2399d6e78f5d5f42cf0c13188c1dba72fe11d73da76a71867d3c3b13052695b868dc4a680fa85b SHA512 ab979aea6ccc6d4faf02b3b1a773ce95cb754b4d687ce7adc2ed98e218f21a284a2283d8e2429016e78fcf5a94ea863011573fd1457a71cc0ae3aadd368a98a1
DIST gpgme-1.15.1.tar.bz2 1699349 BLAKE2B d3a6ccaa35360ed3fc79364dfcc3f2fdcb70e5e41ac72ef011373a39d5def9be9ce1be45843ab65a87630d3fc570d29db5f40b9a273aa8e281464c9d1d3477de SHA512 1d75a848cce6389f7cb8896b57a28dfe1dc5a447bfb4f128b0994a43e04134343400a3be063e971f03dfd595474cfd558519741d5d56afb3e84853ad4f2a45c2
+DIST gpgme-1.16.0.tar.bz2 1718913 BLAKE2B da55e695b148e949a1c0770d0298d7a8c9f87d7a1f9e45d380f8c13c472bd44cb4266adb9a113e2b1dcc2596291744f48fdf998ff2de876059d89d184dc87f3a SHA512 69487be69612e9bf0221ff56ae687248bd13635db1b7087130e93c1670e38f3c810bbca17723555c04fe207976c35871bbc3da005179ce099504321cf33636e4
diff --git a/app-crypt/gpgme/gpgme-1.16.0.ebuild b/app-crypt/gpgme/gpgme-1.16.0.ebuild
new file mode 100644
index 00000000000..9b99df979f9
--- /dev/null
+++ b/app-crypt/gpgme/gpgme-1.16.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_OPTIONAL=1
+
+inherit distutils-r1 flag-o-matic libtool qmake-utils toolchain-funcs
+
+DESCRIPTION="GnuPG Made Easy is a library for making GnuPG easier to use"
+HOMEPAGE="http://www.gnupg.org/related_software/gpgme"
+SRC_URI="mirror://gnupg/gpgme/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="1/11" # subslot = soname major version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="common-lisp static-libs +cxx python qt5"
+
+RDEPEND=">=app-crypt/gnupg-2
+ >=dev-libs/libassuan-2.5.3:=
+ >=dev-libs/libgpg-error-1.36:=
+ python? ( ${PYTHON_DEPS} )
+ qt5? ( dev-qt/qtcore:5 )"
+ #doc? ( app-doc/doxygen[dot] )
+DEPEND="${RDEPEND}
+ qt5? ( dev-qt/qttest:5 )"
+BDEPEND="python? ( dev-lang/swig )"
+
+REQUIRED_USE="qt5? ( cxx ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+do_python() {
+ if use python; then
+ pushd "lang/python" > /dev/null || die
+ top_builddir="../.." srcdir="." CPP=$(tc-getCPP) distutils-r1_src_${EBUILD_PHASE}
+ popd > /dev/null
+ fi
+}
+
+pkg_setup() {
+ addpredict /run/user/$(id -u)/gnupg
+
+ local MAX_WORKDIR=66
+ if [[ "${#WORKDIR}" -gt "${MAX_WORKDIR}" ]]; then
+ ewarn "Disabling tests as WORKDIR '${WORKDIR}' is longer than ${MAX_WORKDIR} which will fail tests"
+ SKIP_TESTS=1
+ fi
+}
+
+src_prepare() {
+ default
+ elibtoolize
+
+ # Make best effort to allow longer PORTAGE_TMPDIR
+ # as usock limitation fails build/tests
+ ln -s "${P}" "${WORKDIR}/b"
+ S="${WORKDIR}/b"
+}
+
+src_configure() {
+ local languages=()
+ use common-lisp && languages+=( "cl" )
+ use cxx && languages+=( "cpp" )
+ if use qt5; then
+ languages+=( "qt" )
+ #use doc ||
+ export DOXYGEN=true
+ export MOC="$(qt5_get_bindir)/moc"
+ fi
+
+ econf \
+ $([[ -n "${SKIP_TESTS}" ]] && echo "--disable-gpg-test --disable-gpgsm-test") \
+ --enable-languages="${languages[*]}" \
+ $(use_enable static-libs static)
+
+ use python && make -C lang/python prepare
+
+ do_python
+}
+
+src_compile() {
+ default
+ do_python
+}
+
+src_test() {
+ [[ -z "${SKIP_TESTS}" ]] || return
+
+ default
+ if use python; then
+ test_python() {
+ emake -C lang/python/tests check \
+ PYTHON=${EPYTHON} \
+ PYTHONS=${EPYTHON} \
+ TESTFLAGS="--python-libdir=${BUILD_DIR}/lib"
+ }
+ python_foreach_impl test_python
+ fi
+}
+
+src_install() {
+ default
+ do_python
+ find "${ED}" -type f -name '*.la' -delete || die
+
+ # backward compatibility for gentoo
+ # in the past we had slots
+ dodir /usr/include/gpgme
+ dosym ../gpgme.h /usr/include/gpgme/gpgme.h
+}