From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1296380-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 59FF713835A
for <garchives@archives.gentoo.org>; Wed, 23 Jun 2021 20:12:37 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id A063DE0917;
Wed, 23 Jun 2021 20:12:36 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 77744E0917
for <gentoo-commits@lists.gentoo.org>; Wed, 23 Jun 2021 20:12:36 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 76497340A85
for <gentoo-commits@lists.gentoo.org>; Wed, 23 Jun 2021 20:12:35 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 0820A7A0
for <gentoo-commits@lists.gentoo.org>; Wed, 23 Jun 2021 20:12:34 +0000 (UTC)
From: "Andrew Ammerlaan" <andrewammerlaan@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andrew Ammerlaan" <andrewammerlaan@gentoo.org>
Message-ID: <1624479151.95591c34ea40fb39e76d73a8ae5b6cf8d25bfc8d.andrewammerlaan@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/spyder/Manifest dev-python/spyder/spyder-5.0.5.ebuild
X-VCS-Directories: dev-python/spyder/
X-VCS-Committer: andrewammerlaan
X-VCS-Committer-Name: Andrew Ammerlaan
X-VCS-Revision: 95591c34ea40fb39e76d73a8ae5b6cf8d25bfc8d
X-VCS-Branch: master
Date: Wed, 23 Jun 2021 20:12:34 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 24a8a9b6-570e-48ed-a2ae-b3241c012c50
X-Archives-Hash: debb9c57d2c2f56c0312f5ada98f0f45
commit: 95591c34ea40fb39e76d73a8ae5b6cf8d25bfc8d
Author: Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 23 20:11:17 2021 +0000
Commit: Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed Jun 23 20:12:31 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=95591c34
dev-python/spyder: add version 5.0.5
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>
dev-python/spyder/Manifest | 2 +
dev-python/spyder/spyder-5.0.5.ebuild | 209 ++++++++++++++++++++++++++++++++++
2 files changed, 211 insertions(+)
diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index fe331f3b132..d02ec00b838 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,4 +1,6 @@
DIST spyder-4.2.5.tar.gz 11539071 BLAKE2B 9d7a98da018aae934803d640995fe2dfa6bbb20bfc7140bd00f5e7a00a09c47922fefd8df84f4b217a50176ee190515da6f4cbf498a03cae68e2ac4f5ec70664 SHA512 081b047a45b7522a69b1b21a221ab5cdef47f87f36ed4423ff63297d205f924c1627517c50622acb2d10efa094bc506fed4ec88f861775d3f58e81ac6ef017ac
DIST spyder-5.0.4.tar.gz 20606964 BLAKE2B 20042d3d9b10da32aafe4036332608faa4bee458f36fb9359237cf2fd0651db68d8c7fb2a1bf653a350dcbd92fde856a4d37b4a8f85a37dffc6f8f31c750cbb3 SHA512 221c7b545d932a5c70f3f179b188f6ad9c2b1c632771f6766cba32115d1df56135708adbe2417c2236dc4b4fe847a734eaf1fb2920cad5b5e94969c308792d93
+DIST spyder-5.0.5.tar.gz 20606379 BLAKE2B 52f05ffcf0b6aabdac23a055af1c674c6aa80a7d4f3608779df1d46e0e51de63a71b4e97db286dc92e071cbb44a0dc827aa750d8ca538e6764b5e780f493d615 SHA512 17654ee76eb51c5f5b9f494d009af3d7813f869f27f22ceb8ad8ca96dcedcbcd6b86c7a3895bb63eba3cc60e4a57ab94128abb8d21f05c4672b8bb8d545fe1ff
+DIST spyder-docs-6ebb1ace2d7ce94e45e8b2c1b7ddb53395f86e67.tar.gz 78446300 BLAKE2B 4225589581ef47237d7025f506812840c959e589cddfe47d2c4d3a74d7fc876f67eda291ad07e82b054ff2666bed34fa0edca1e1c0e1ff5574efb2db1028a42a SHA512 4d0bd348ec3335e022456c19dc319295948061cea45b0f1e5a05c2640943776b5c3bdc2581fdc0571bd98fe8834af035134084394ce6711d5a69598515bd0e9b
DIST spyder-docs-78b25754c69a20643258821146e398ad5535c920.tar.gz 69167467 BLAKE2B d2815d552002f329b5fac59329fba3b3b0cd592bcbdacc0878966919e44dbab29548533661e60a1b9b8fd763d57d1e4c2f761782ace1b0a814a5f0cec1f66af9 SHA512 10764367fd5f830d7a3620b9d9e7ec4ab74539c1f48326c0c40f7caff74a50401addc7609fe1558c57dac4649d0a214c0d2d77cecd100bd8574151134e49634d
DIST spyder-docs-b317961de7600fc906d862238f344b3a315d28b1.tar.gz 80326831 BLAKE2B 0e9bb5d52c3cc1615f74f31a2c87be9fca5431bd19975594e147b5f9f3082f16f0cdfc476402533a0950bd928fda55de6c3850ed3a2780f1439fe88e349bf0f2 SHA512 8a1fe8e88c029402743c15b720e2e889fdbb73999a1035e81e5b3f998992515e041e14d8e361e23e7ec8a02cf30706349d12e9e0b37df9d1d7554b926831af78
diff --git a/dev-python/spyder/spyder-5.0.5.ebuild b/dev-python/spyder/spyder-5.0.5.ebuild
new file mode 100644
index 00000000000..eb12c15ca98
--- /dev/null
+++ b/dev-python/spyder/spyder-5.0.5.ebuild
@@ -0,0 +1,209 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit optfeature xdg distutils-r1
+
+# Commit of documentation to fetch
+DOCS_PV="6ebb1ace2d7ce94e45e8b2c1b7ddb53395f86e67"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+ https://www.spyder-ide.org/
+ https://github.com/spyder-ide/spyder/
+ https://pypi.org/project/spyder/
+"
+SRC_URI="
+ https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+ https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# The test suite often hangs or does not work. Technically spyder requires
+# pyqt5<13, which we do not have in ::gentoo any more. Likely this is the reason
+# many of the tests fail or hang. RESTRICTing because IMO it is not worth the
+# several hours I spend every single version bump checking which tests do and
+# do not work. Spyder itself works fine with pyqt5>13.
+RESTRICT="test"
+
+RDEPEND="
+ >=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+ >=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/cloudpickle-0.5.0[${PYTHON_USEDEP}]
+ >=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+ >=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+ >=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+ >=dev-python/ipython-7.6.0[${PYTHON_USEDEP}]
+ ~dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+ >=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+ >=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+ >=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+ >=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+ ~dev-python/parso-0.7.0[${PYTHON_USEDEP}]
+ >=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+ >=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+ >=dev-python/pylint-1.0[${PYTHON_USEDEP}]
+ >=dev-python/python-lsp-black-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+ >=dev-python/python-lsp-server-1.0.1[${PYTHON_USEDEP}]
+ >=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+ >=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+ ~dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
+ >=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
+ >=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
+ >=dev-python/qtconsole-5.1.0[${PYTHON_USEDEP}]
+ >=dev-python/QtPy-1.5.0[${PYTHON_USEDEP},pyqt5(+),svg,webengine]
+ >=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+ >=dev-python/spyder-kernels-2.0.4[${PYTHON_USEDEP}]
+ <dev-python/spyder-kernels-2.1.0[${PYTHON_USEDEP}]
+ >=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+ >=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+ >=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+"
+
+# python-lsp-server[all] deps
+RDEPEND+="
+ dev-python/autopep8[${PYTHON_USEDEP}]
+ >=dev-python/flake8-3.8.0[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+ >=dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
+ >=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
+ <dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+ dev-python/yapf[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ test? (
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/flaky[${PYTHON_USEDEP}]
+ dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+ dev-python/pandas[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ <dev-python/pytest-6.0[${PYTHON_USEDEP}]
+ dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/pytest-ordering[${PYTHON_USEDEP}]
+ <dev-python/pytest-qt-4[${PYTHON_USEDEP}]
+ dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ dev-python/sympy[${PYTHON_USEDEP}]
+ )"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+ "${FILESDIR}/${PN}-5.0.0-build.patch"
+ "${FILESDIR}/${PN}-5.0.1-doc-theme-renamed.patch"
+)
+
+DOCS=(
+ "AUTHORS.txt"
+ "Announcements.md"
+ "CHANGELOG.md"
+ "CODE_OF_CONDUCT.md"
+ "CONTRIBUTING.md"
+ "NOTICE.txt"
+ "README.md"
+ "RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc \
+ dev-python/sphinx-panels \
+ dev-python/pydata-sphinx-theme \
+ dev-python/sphinx-multiversion
+
+python_prepare_all() {
+ # move docs into workdir
+ mv ../spyder-docs-${DOCS_PV}* docs || die
+
+ # these dependencies are packaged separately:
+ # dev-python/spyder-kernels,
+ # dev-python/python-language-server,
+ # dev-python/qdarkstyle
+ rm -r external-deps/* || die
+ # runs against things packaged in external-deps dir
+ rm conftest.py || die
+
+ # Use the spyder fork of pyls (python-lsp-server instead of python-language-server)
+ # The original hasn't been update in over 6 months, and spyder upstream is slow
+ # in making the switch. Because we are running into issues with outdated deps
+ # and a whole dependency mess as a result, we can no longer wait for upstream.
+ find . -name "*.py" -exec sed -i \
+ -e 's/python-language-server\[all\]>=0.36.2,<1.0.0/python-lsp-server\[all\]>=1.0.0/g' \
+ -e 's/python-language-server/python-lsp-server/g' \
+ -e 's/python_language_server/python_lsp_server/g' \
+ -e 's/python-jsonrpc-server/python-lsp-jsonrpc/g' \
+ -e 's/python_jsonrpc_server/python_lsp_jsonrpc/g' \
+ -e 's/pyls/pylsp/g' \
+ -e 's/pylsp-spyder/pyls-spyder/g' \
+ -e 's/pylsp_spyder/pyls_spyder/g' \
+ -e 's/pyls-spyder>=0.3.2,<0.4.0/pyls-spyder>=0.4.0/g' \
+ -e 's/pylsp-black/python-lsp-black/g' \
+ -e 's/>=0.3.2;<0.4.0/>=0.4.0/g' \
+ -e 's/>=0.36.2;<1.0.0/>=1.0.0/g' \
+ {} + || die
+
+ # do not depend on pyqt5<13
+ sed -i -e '/pyqt5/d' \
+ -e '/pyqtwebengine/d' \
+ setup.py || die
+
+ # do not check deps, fails because we removed pyqt5 dependency above
+ sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+ spyder/tests/test_dependencies_in_sync.py || die
+
+ # can't check for update, need network
+ rm spyder/workers/tests/test_update.py || die
+
+ # skip online test
+ rm spyder/widgets/github/tests/test_github_backend.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly makes the tests freeze after completing even if successful
+# Exit code is nonzero even upon success, so can't add || die here test results
+# should be checked for success manually
+python_test() {
+ "${EPYTHON}" runtests.py
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+ optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+ optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+ optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+ optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+ optfeature "Run Cython files in the IPython console" dev-python/cython
+ optfeature "The hdf5/h5py plugin" dev-python/h5py
+ optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+ optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+ # spyder-autopep8 does not have a release (yet)
+ # and are not compatible with >=spyder-4.0.0 at the moment
+ # optfeature "The autopep8 plugin" dev-python/spyder-autopep8
+ optfeature "Vim key bindings" dev-python/spyder-vim
+ optfeature "Unittest support" dev-python/spyder-unittest
+ optfeature "Jupyter notebook support" dev-python/spyder-notebook
+ optfeature "System terminal inside spyder" dev-python/spyder-terminal
+ # spyder-reports not yet updated to >=spyder-4.0.0
+ # optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+}