[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

["Sam James" <sam@gentoo.org>]

commit:     5ef9c38ce9bf7848f074a8d3729318e2918345c6
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 16 12:27:40 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Jun 16 12:32:00 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ef9c38c

kde-plasma/plasma-firewall: 5.22.1 version bump

Signed-off-by: Sam James <sam <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.22.1.ebuild  | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index dd7c41f353a..12831f5088b 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.21.5.tar.xz 331812 BLAKE2B 43a026a198fb61480e90c5a5235de1abbb106e3f78d4a81fe919ec8c65c4f5ca30b340436b28369d8797d9ad1eac87fd0a4e39b5e3670f68150992e6007c4a76 SHA512 93d36b12025f1918892ad02e6b92dc8c44c27d2c6426a19fb77d8b258940a25295acd923b3957d45eb1715dae097097368b0456bf27273c217b79b441dec55fd
 DIST plasma-firewall-5.22.0.tar.xz 339052 BLAKE2B 24838f427471415a0083c093b3d76803435d8c4a60fdf5780119fbaf77ac7aef5c29a9b7ee806cfd9bfdd69c1d96c07bf58a0e75ff0a407fd1d4b6a5c0b7de29 SHA512 500324331383c9aff899dbf9c78ec76c5ca468b1a06603b30d72763b88ed8f538b1c9d4cbae1e8b5777d0b1073710806db81601637d80f0fbead1471724cc5f5
+DIST plasma-firewall-5.22.1.tar.xz 339052 BLAKE2B 9448edd183abbf55364431336f0a96d72b4ee214bf43852b5ce57a52866de9a69cb6e2ccb86690a55d653cf5937f66857e4e7270b35bc151ddf585ea39b6a0e1 SHA512 f89c3a15d402066f42765a0a241a33b88fe0b6c1898297445968a8f8f236488cbb7b1b279af1d902c827338cb3cf040fb774ae65d5642ecd69267319fd89852a

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.22.1.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.22.1.ebuild
new file mode 100644
index 00000000000..622d3b7334c
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.22.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9} )
+KFMIN=5.82.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env python3.8:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}