[gentoo-commits] repo/gentoo:master commit in: net-ftp/proftpd/

["Sergei Trofimovich" <slyfox@gentoo.org>]

commit:     a1ab8db85a0e1db820764d0517b71008cd35919f
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 15 07:15:49 2021 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Tue Jun 15 07:15:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a1ab8db8

net-ftp/proftpd: bump up to 1.3.7b

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 net-ftp/proftpd/Manifest              |   1 +
 net-ftp/proftpd/proftpd-1.3.7b.ebuild | 273 ++++++++++++++++++++++++++++++++++
 2 files changed, 274 insertions(+)

diff --git a/net-ftp/proftpd/Manifest b/net-ftp/proftpd/Manifest
index 9c964150214..179fffe5777 100644
--- a/net-ftp/proftpd/Manifest
+++ b/net-ftp/proftpd/Manifest
@@ -1,6 +1,7 @@
 DIST mod_gss-1.3.9.tar.gz 117158 BLAKE2B f957fa465f9a9b06ceb9c190ab60c7f67fdeeef79dce7f51bcfed8dc726cb01a231232c65821ca3a240b77a5019fa22f31b45496c128a06627bd24dc960b566f SHA512 44615983b0f67939b110e54c4a83b3056263bad72ba78de1b16f9f8590f5504c60e679f55484708d49e694c528d4715d9abd0cb75cfe439982ea9e02e0c18891
 DIST mod_vroot-0.9.4.tar.gz 29461 BLAKE2B eb4d3f6425ab0a1a61ca607e4655b5f8ff6ea342ca49d49598e7a4c5596382aa2c1d4e8228a1cdcfff324feb92dac80fcc58e35bbb77155069749afdd7cc41fb SHA512 f5de392c9fe39f0a03b0783a7092bbfe17ea6db991f4b4e4a2d8f092f073d27ef2c64dd6484d5665b5abc808c0caba016d4fc3fab3da3810f5ebe5249bb4cbce
 DIST proftpd-1.3.7a.tar.gz 20414571 BLAKE2B 829f3ff79cf74bc9cacfc611877cd1373daefb022b10eb427be56325d455dc7ba2f87a7dbefed06dca0c4cf06597043aac9141e4156e775a4f343bbb07a29375 SHA512 abb53c494677001b6d8d5a15af4ae47e2527025c952667b8c42e144452266d2b7f89b57e68c96177e6054733eb5e5d04cc1c0cf61ff7c3697910e0a525a9de87
+DIST proftpd-1.3.7b.tar.gz 20422741 BLAKE2B 9234d395348778c208307928ae7d673078edf01d9d4e46501b2f46dc051bb0debb1cae0d81ac1564b4e6828a07dae6bdd1b5e708449bb2e21acf6ee1aedfb1f2 SHA512 c25dbd3d5359a41d9f2bc81f130af5c9448000626b27e9e9228efcfdd4c01e109bb19bdb7de46d7368911114b135a43c8b0ad4170c9215a87e93e56108de889a
 DIST proftpd-mod-case-0.7.tar.gz 13184 BLAKE2B bf2118d9b8ed97a5b192b92b515d17ac7a0d75e154288e5afb3a1c3d686e635093df9501cc1c9b077f87c14326e31e8b9f751803dfca1eae9643f12333eb633f SHA512 c08d13ef82fec36ae75aa3213dd02e0ce4045904849f422e152f039a9da66a45e4423751074b8bcf8ce347a40ce0e7bde798a85cbadc962fd872aeaa898261fc
 DIST proftpd-mod-diskuse-0.9.tar.gz 18596 BLAKE2B 38c704c8607f0f93b080e77fe793cfe0125c88acc6f818ecb059c6c21a983e040ff5f2c1b91e34ef4ba2666a808d896018c364d1f12ea38f0c477e79bdaa2120 SHA512 d41976bf2810e4b783e775e8c767ca2030c3b5df116219fd31cbbac7feaf9922c315bf4ea092881b0d6cf43f2f4c5dbcae61be3c3a833058d12f962a3024b975
 DIST proftpd-mod-msg-0.4.1.tar.gz 8082 BLAKE2B 970b46b19d25bac22ecb01495270a523997a0b7d5b53b9470b4744b919adcf03d5bcee2df85ba88c4a4c20a9fc30dc01459ffb58c5dae8e78a52a7379bf36f11 SHA512 38ea63b1d355e1e10a6a4477596bf3fa28529a871c9fb8dbf093b5317f0743ef9cb59b986d0b8c1c7ed932dad5d5d571883d596fad2d3b793431824db4487012

diff --git a/net-ftp/proftpd/proftpd-1.3.7b.ebuild b/net-ftp/proftpd/proftpd-1.3.7b.ebuild
new file mode 100644
index 00000000000..14f41fdcfdd
--- /dev/null
+++ b/net-ftp/proftpd/proftpd-1.3.7b.ebuild
@@ -0,0 +1,273 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib systemd tmpfiles toolchain-funcs
+
+MOD_CASE="0.7"
+MOD_CLAMAV="0.14rc2"
+MOD_DISKUSE="0.9"
+MOD_GSS="1.3.9"
+MOD_MSG="0.4.1"
+MOD_VROOT="0.9.4"
+
+DESCRIPTION="An advanced and very configurable FTP server"
+HOMEPAGE="http://www.proftpd.org/
+	http://www.castaglia.org/proftpd/
+	https://github.com/jbenden/mod_clamav
+	http://gssmod.sourceforge.net/"
+SRC_URI="ftp://ftp.proftpd.org/distrib/source/${P/_/}.tar.gz
+	case? ( http://www.castaglia.org/${PN}/modules/${PN}-mod-case-${MOD_CASE}.tar.gz )
+	clamav? ( https://github.com/jbenden/mod_clamav/archive/v${MOD_CLAMAV}.tar.gz -> ${PN}-mod_clamav-${MOD_CLAMAV}.tar.gz )
+	diskuse? ( http://www.castaglia.org/${PN}/modules/${PN}-mod-diskuse-${MOD_DISKUSE}.tar.gz )
+	kerberos? ( mirror://sourceforge/gssmod/mod_gss-${MOD_GSS}.tar.gz )
+	msg? ( http://www.castaglia.org/${PN}/modules/${PN}-mod-msg-${MOD_MSG}.tar.gz )
+	vroot? ( https://github.com/Castaglia/${PN}-mod_vroot/archive/v${MOD_VROOT}.tar.gz -> mod_vroot-${MOD_VROOT}.tar.gz )"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="acl authfile ban +caps case clamav copy ctrls deflate diskuse dso dynmasq exec ifsession ifversion ident ipv6
+	kerberos ldap log-forensic memcache msg mysql ncurses nls pam +pcre postgres qos radius
+	ratio readme rewrite selinux sftp shaper sitemisc snmp sodium softquota sqlite ssl tcpd test unique-id vroot"
+# TODO: geoip
+REQUIRED_USE="ban? ( ctrls )
+	msg? ( ctrls )
+	sftp? ( ssl )
+	shaper? ( ctrls )
+
+	mysql? ( ssl )
+	postgres? ( ssl )
+	sqlite? ( ssl )
+"
+
+CDEPEND="acl? ( virtual/acl )
+	caps? ( sys-libs/libcap )
+	clamav? ( app-antivirus/clamav )
+	kerberos? ( virtual/krb5 )
+	ldap? ( net-nds/openldap )
+	memcache? ( >=dev-libs/libmemcached-0.41 )
+	mysql? ( dev-db/mysql-connector-c:0= )
+	nls? ( virtual/libiconv )
+	ncurses? ( sys-libs/ncurses:0= )
+	ssl? ( dev-libs/openssl:0= )
+	pam? ( sys-libs/pam )
+	pcre? ( dev-libs/libpcre )
+	postgres? ( dev-db/postgresql:= )
+	sodium? ( dev-libs/libsodium:0= )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${CDEPEND}
+	test? ( dev-libs/check )"
+RDEPEND="${CDEPEND}
+	net-ftp/ftpbase
+	selinux? ( sec-policy/selinux-ftp )"
+
+S="${WORKDIR}/${P/_/}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.6-use-trace.patch
+	"${FILESDIR}"/${PN}-1.3.7a-slibtool.patch
+)
+
+RESTRICT=test # Some tests are ran in chroot. Confuse sandbox.
+
+in_dir() {
+	pushd "${WORKDIR}/${1}" || die
+	shift
+	"$@"
+	popd
+}
+
+src_prepare() {
+	# Skip 'install-conf' / Support LINGUAS
+	sed -i -e "/install-all/s/ install-conf//" Makefile.in || die
+	sed -i -e "s/^LANGS=.*$/LANGS=${LINGUAS}/" locale/Makefile.in || die
+
+	# Prepare external modules
+	if use case; then
+		cp -v "${WORKDIR}"/mod_case/mod_case.c contrib || die
+		cp -v "${WORKDIR}"/mod_case/mod_case.html doc/contrib || die
+	fi
+
+	if use clamav ; then
+		cp -v "${WORKDIR}"/mod_clamav-${MOD_CLAMAV}/mod_clamav.{c,h} contrib || die
+		eapply -p0 "${WORKDIR}"/mod_clamav-${MOD_CLAMAV}/001-add-mod_clamav-to-tests.patch
+	fi
+
+	if use diskuse; then
+		in_dir mod_diskuse eapply "${FILESDIR}"/${PN}-1.3.6_rc4-diskuse-refresh-api.patch
+
+		# ./configure will modify files. Symlink them instead of copying
+		ln -sv "${WORKDIR}"/mod_diskuse/mod_diskuse.h "${S}"/contrib || die
+
+		cp -v "${WORKDIR}"/mod_diskuse/mod_diskuse.c "${S}"/contrib || die
+		cp -v "${WORKDIR}"/mod_diskuse/mod_diskuse.html "${S}"/doc/contrib || die
+	fi
+
+	if use msg; then
+		in_dir mod_msg eapply "${FILESDIR}"/${PN}-1.3.6_rc4-msg-refresh-api.patch
+
+		cp -v "${WORKDIR}"/mod_msg/mod_msg.c contrib || die
+		cp -v "${WORKDIR}"/mod_msg/mod_msg.html doc/contrib || die
+	fi
+
+	if use vroot; then
+		in_dir ${PN}-mod_vroot-${MOD_VROOT} eapply "${FILESDIR}"/${PN}-1.3.6_rc4-vroot-refresh-api.patch
+
+		cp -v "${WORKDIR}"/${PN}-mod_vroot-${MOD_VROOT}/mod_vroot.c contrib || die
+		cp -v "${WORKDIR}"/${PN}-mod_vroot-${MOD_VROOT}/mod_vroot.html doc/contrib || die
+	fi
+
+	if use kerberos ; then
+		# in_dir mod_gss-${MOD_GSS} eapply "${FILESDIR}"/${PN}-1.3.6_rc4-gss-refresh-api.patch
+
+		# Support app-crypt/heimdal / Gentoo Bug #284853
+		sed -i -e "s/krb5_principal2principalname/_\0/" "${WORKDIR}"/mod_gss-${MOD_GSS}/mod_auth_gss.c.in || die
+
+		# Remove obsolete DES / Gentoo Bug #324903
+		# Replace 'rpm' lookups / Gentoo Bug #391021
+		sed -i -e "/ac_gss_libs/s/ -ldes425//" \
+			-e "s/ac_libdir=\`rpm -q -l.*$/ac_libdir=\/usr\/$(get_libdir)\//" \
+			-e "s/ac_includedir=\`rpm -q -l.*$/ac_includedir=\/usr\/include\//" "${WORKDIR}"/mod_gss-${MOD_GSS}/configure{,.ac}  || die
+
+		# ./configure will modify files. Symlink them instead of copying
+		ln -sv "${WORKDIR}"/mod_gss-${MOD_GSS}/mod_auth_gss.c "${S}"/contrib || die
+		ln -sv "${WORKDIR}"/mod_gss-${MOD_GSS}/mod_gss.c "${S}"/contrib || die
+		ln -sv "${WORKDIR}"/mod_gss-${MOD_GSS}/mod_gss.h "${S}"/include || die
+
+		cp -v "${WORKDIR}"/mod_gss-${MOD_GSS}/README.mod_{auth_gss,gss} "${S}" || die
+		cp -v "${WORKDIR}"/mod_gss-${MOD_GSS}/mod_gss.html "${S}"/doc/contrib || die
+		cp -v "${WORKDIR}"/mod_gss-${MOD_GSS}/rfc{1509,2228}.txt "${S}"/doc/rfc || die
+	fi
+
+	default
+
+	tc-export CC
+}
+
+src_configure() {
+	local c m
+
+	use acl && m="${m}:mod_facl"
+	use ban && m="${m}:mod_ban"
+	use case && m="${m}:mod_case"
+	use clamav && m="${m}:mod_clamav"
+	use copy && m="${m}:mod_copy"
+	use ctrls && m="${m}:mod_ctrls_admin"
+	use deflate && m="${m}:mod_deflate"
+	if use diskuse ; then
+		in_dir mod_diskuse econf
+		m="${m}:mod_diskuse"
+	fi
+	use dynmasq && m="${m}:mod_dynmasq"
+	use exec && m="${m}:mod_exec"
+	use ifsession && m="${m}:mod_ifsession"
+	use ifversion && m="${m}:mod_ifversion"
+	if use kerberos ; then
+		in_dir mod_gss-${MOD_GSS} econf
+		m="${m}:mod_gss:mod_auth_gss"
+	fi
+	use ldap && m="${m}:mod_ldap"
+	use log-forensic && m="${m}:mod_log_forensic"
+	use msg && m="${m}:mod_msg"
+	if use mysql || use postgres || use sqlite ; then
+		m="${m}:mod_sql:mod_sql_passwd"
+		use mysql && m="${m}:mod_sql_mysql"
+		use postgres && m="${m}:mod_sql_postgres"
+		use sqlite && m="${m}:mod_sql_sqlite"
+	fi
+	use qos && m="${m}:mod_qos"
+	use radius && m="${m}:mod_radius"
+	use ratio && m="${m}:mod_ratio"
+	use readme && m="${m}:mod_readme"
+	use rewrite && m="${m}:mod_rewrite"
+	if use sftp ; then
+		m="${m}:mod_sftp"
+		use pam && m="${m}:mod_sftp_pam"
+		use mysql || use postgres || use sqlite && m="${m}:mod_sftp_sql"
+	fi
+	use shaper && m="${m}:mod_shaper"
+	use sitemisc && m="${m}:mod_site_misc"
+	use snmp && m="${m}:mod_snmp"
+	if use softquota ; then
+		m="${m}:mod_quotatab:mod_quotatab_file"
+		use ldap && m="${m}:mod_quotatab_ldap"
+		use radius && m="${m}:mod_quotatab_radius"
+		use mysql || use postgres || use sqlite && m="${m}:mod_quotatab_sql"
+	fi
+	if use ssl ; then
+		m="${m}:mod_tls:mod_tls_shmcache"
+		use memcache && m="${m}:mod_tls_memcache"
+	fi
+	if use tcpd ; then
+		m="${m}:mod_wrap2:mod_wrap2_file"
+		use mysql || use postgres || use sqlite && m="${m}:mod_wrap2_sql"
+	fi
+	use unique-id && m="${m}:mod_unique_id"
+	use vroot && m="${m}:mod_vroot"
+
+	if [[ -n ${PROFTP_CUSTOM_MODULES} ]]; then
+		einfo "Adding user-specified extra modules: '${PROFTP_CUSTOM_MODULES}'"
+		m="${m}:${PROFTP_CUSTOM_MODULES}"
+	fi
+
+	[[ -z ${m} ]] || c="${c} --with-modules=${m:1}"
+
+	econf --localstatedir=/run/proftpd --sysconfdir=/etc/proftpd --disable-strip \
+		$(use_enable acl facl) \
+		$(use_enable authfile auth-file) \
+		$(use_enable caps cap) \
+		$(use_enable ctrls) \
+		$(use_enable dso) \
+		$(use_enable ident) \
+		$(use_enable ipv6) \
+		$(use_enable memcache) \
+		$(use_enable ncurses) \
+		$(use_enable nls) \
+		$(use_enable ssl openssl) \
+		$(use_enable pam auth-pam) \
+		$(use_enable pcre) \
+		$(use_enable sodium) \
+		$(use_enable test tests) \
+		--enable-trace \
+		$(use_enable userland_GNU shadow) \
+		$(use_enable userland_GNU autoshadow) \
+		${c:1}
+}
+
+src_test() {
+	emake api-tests -C tests
+}
+
+src_install() {
+	default
+	[[ -z ${LINGUAS-set} ]] && rm -r "${ED}"/usr/share/locale
+	rm -rf "${ED}"/run "${ED}"/var/run
+
+	newinitd "${FILESDIR}"/proftpd.initd-r1 proftpd
+	insinto /etc/proftpd
+	doins "${FILESDIR}"/proftpd.conf.sample
+
+	insinto /etc/xinetd.d
+	newins "${FILESDIR}"/proftpd.xinetd proftpd
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	dodoc ChangeLog CREDITS INSTALL NEWS README* RELEASE_NOTES
+
+	docinto html
+	dodoc doc/*.html doc/contrib/*.html doc/howto/*.html doc/modules/*.html
+
+	docinto rfc
+	dodoc doc/rfc/*.txt
+
+	systemd_dounit       "${FILESDIR}"/${PN}.service
+	newtmpfiles "${FILESDIR}"/${PN}-tmpfiles.d.conf-r1 ${PN}.conf
+}
+
+pkg_postinst() {
+	# Create /var/run files at package merge time: bug #650000
+	tmpfiles_process ${PN}.conf
+}