[gentoo-commits] repo/gentoo:master commit in: dev-python/vdirsyncer/

["Michał Górny" <mgorny@gentoo.org>]

commit:     9531eeb262e56498ba9cc53c51c74c259a17d67f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 14 06:35:10 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jun 14 06:51:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9531eeb2

dev-python/vdirsyncer: Bump to 0.18.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/vdirsyncer/Manifest                 |  1 +
 dev-python/vdirsyncer/vdirsyncer-0.18.0.ebuild | 49 ++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/vdirsyncer/Manifest b/dev-python/vdirsyncer/Manifest
index 438496531cd..29341dd12fe 100644
--- a/dev-python/vdirsyncer/Manifest
+++ b/dev-python/vdirsyncer/Manifest
@@ -1 +1,2 @@
 DIST vdirsyncer-0.16.8.tar.gz 115819 BLAKE2B e0140718a1b41875421a7094e02cdeb865c500935e0c97bc18a614551586d79682641726df1a96e17a158604ed309f713f4caf4a484025eca5fbc6acbbe18f97 SHA512 12cb50f592085af37bd9c4207c0d31fdd38fc2a44712eb6288b12e7e7ee9af82070d1d405fa9579e935e545e6c92aafb6f8334ebde4976c4eb9412e78e7c5ada
+DIST vdirsyncer-0.18.0.tar.gz 115125 BLAKE2B d81bb9b51658d16a3b9ea044846561a1ce2dac3a839d7e0a165f0136069fcd0716525ab2b908be7cafed60846a1aed6fd72aa1d31fc2a38dbe6de8d0e6585226 SHA512 7fb3d0f7d982d8390d278de1a620231e6ead1ec64057c5dbac98dcff491fa3e6b9ed8ba953995458e393aab73b0b9ab8ba14010e06f90a04d8ee2c28c7c7fbfd

diff --git a/dev-python/vdirsyncer/vdirsyncer-0.18.0.ebuild b/dev-python/vdirsyncer/vdirsyncer-0.18.0.ebuild
new file mode 100644
index 00000000000..05fd220b6b8
--- /dev/null
+++ b/dev-python/vdirsyncer/vdirsyncer-0.18.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Synchronize calendars and contacts"
+HOMEPAGE="https://github.com/pimutils/vdirsyncer"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+SLOT="0"
+
+PATCHES=( "${FILESDIR}/${PN}-0.16.8-click-7-compat.patch" )
+
+RDEPEND="dev-python/click[${PYTHON_USEDEP}]
+	>=dev-python/click-log-0.3.0[${PYTHON_USEDEP}]
+	<dev-python/click-log-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/click-threading-0.5[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	dev-python/atomicwrites[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pytest-subtesthack[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( AUTHORS.rst CHANGELOG.rst CONTRIBUTING.rst README.rst config.example )
+
+distutils_enable_tests pytest
+
+python_test() {
+	# skip tests needing servers running
+	local -x DAV_SERVER=skip
+	local -x REMOTESTORAGE_SERVER=skip
+	# pytest dies hard if the envvars do not have any value...
+	local -x CI=false
+	local -x DETERMINISTIC_TESTS=false
+	epytest
+}