[gentoo-commits] repo/gentoo:master commit in: dev-libs/libcharon/

["Dennis Lamm" <expeditioneer@gentoo.org>]

commit:     3f456ecd53c42a7dd56df8a2ef51f3cffd57901d
Author:     Mathy Vanvoorden <mathy <AT> vanvoorden <DOT> be>
AuthorDate: Mon Jun  7 15:57:40 2021 +0000
Commit:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
CommitDate: Thu Jun 10 17:40:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3f456ecd

dev-libs/libcharon: Version bump to 4.9.1

Closes: https://bugs.gentoo.org/793803
Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Mathy Vanvoorden <mathy <AT> vanvoorden.be>
Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>

 dev-libs/libcharon/Manifest               |  1 +
 dev-libs/libcharon/libcharon-4.9.1.ebuild | 73 +++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-libs/libcharon/Manifest b/dev-libs/libcharon/Manifest
index 0e334c6a336..3764ed0bee8 100644
--- a/dev-libs/libcharon/Manifest
+++ b/dev-libs/libcharon/Manifest
@@ -1 +1,2 @@
 DIST libcharon-4.8.0.tar.gz 151223 BLAKE2B fe4d2901908367569b45c466d31ac6e290979a8bd39c84f9c3ceb3ed91e9d9f1a789703fa5006706e21d77bd46b3185571df3f6157c7722e3e35244d27e0231c SHA512 33d3e9aa4e356fbf1d41555cfe2a5470d8f02b1d4f59d83e1ba89236b5e4489a93bdf24fad6f9bd2b0f843c053c485a082f5ee57437862ac40522aa61280b19c
+DIST libcharon-4.9.1.tar.gz 151243 BLAKE2B 8557efe4667a83297a4bcfc8307e2322a379e52d50ad1648d873a923e182b3be1651a13c7402ac041fd134036a75a42e825adf2cc27271af218db44af7e48473 SHA512 41d611f8d3bf0f762a38a00c159104df04b73cd5c4f7e9ebcfe3ac9cdd0c8e31e505c4fd4ef8f8a6f1c02bf882bb3e14ea4e92c8b15169a91cbd1815e36310fa

diff --git a/dev-libs/libcharon/libcharon-4.9.1.ebuild b/dev-libs/libcharon/libcharon-4.9.1.ebuild
new file mode 100644
index 00000000000..f7557d50913
--- /dev/null
+++ b/dev-libs/libcharon/libcharon-4.9.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit cmake python-single-r1
+
+MY_PN="libCharon"
+
+DESCRIPTION="This library facilitates communication between Cura and its backend"
+HOMEPAGE="https://github.com/Ultimaker/libCharon"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+client +dbus test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="
+	${PYTHON_DEPS}
+	dbus? (
+		acct-group/ultimaker
+		acct-user/ultimaker
+		sys-apps/dbus
+	)"
+
+DEPEND="${PYTHON_DEPS}
+	test? (
+		$(python_gen_cond_dep 'dev-python/pytest[${PYTHON_MULTI_USEDEP}]')
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	# use current python version, not the latest installed
+	# fix python install location
+	sed -i \
+		-e "s:find_package(Python3 3.4 REQUIRED:find_package(Python3 ${EPYTHON##python} EXACT REQUIRED:g" \
+		-e "s:lib\${LIB_SUFFIX}/python\${Python3_VERSION_MAJOR}\.\${Python3_VERSION_MINOR}/site-packages:$(python_get_sitedir):g" \
+		CMakeLists.txt || die
+
+	sed -i -e "s:/usr/lib/python3/dist-packages/Charon/Service/main.py:$(python_get_sitedir)/Charon/Service/main.py:g" service/charon.service || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_CLIENT=$(usex client ON OFF)
+		-DINSTALL_SERVICE=$(usex dbus ON OFF)
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	python_optimize "${D}/usr/$(get_libdir)"
+}
+
+pkg_postinst() {
+	if use dbus ; then
+		elog "To start the Charon File Metadata service at boot, add it to the default runlevel with:"
+		elog "    systemctl enable charon"
+	fi
+}