[gentoo-commits] repo/gentoo:master commit in: app-misc/pax-utils/

["Sergei Trofimovich" <slyfox@gentoo.org>]

commit:     b390c1cbeb6ea6ea68b361342f872e5ab275ba8c
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 10 07:21:17 2021 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Thu Jun 10 07:21:33 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b390c1cb

app-misc/pax-utils: bump up to 1.3.2

Two new changes:
- lddtree: respect (destination) root with --argv0 interp probing
- seccomp: fix build failure on mips (use _MIP_SIM tests)

Fixed-by: Manuel Lauss
Closes: https://bugs.gentoo.org/795075
Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 app-misc/pax-utils/Manifest               |  1 +
 app-misc/pax-utils/pax-utils-1.3.2.ebuild | 75 +++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/app-misc/pax-utils/Manifest b/app-misc/pax-utils/Manifest
index 7445dcee28b..788ef159a40 100644
--- a/app-misc/pax-utils/Manifest
+++ b/app-misc/pax-utils/Manifest
@@ -1 +1,2 @@
 DIST pax-utils-1.3.1.tar.xz 718384 BLAKE2B eef34077dfaceba1bf6f3d56b5e9990090e6d6c5d8c14f7f4bd8506040f0abdcf1a7bd52c643092faa74d991f22ed48c96924572a50c556aaf879dd411569457 SHA512 1a3a463f3864a420b4dcdd8e5736fbee785ed7cb19545966819493cc98d3cea670eb44592c7f100188b2d45b58908bc1f8e2e010f8842c51b70495b260a03102
+DIST pax-utils-1.3.2.tar.xz 725916 BLAKE2B ff792288b22c185501123d3e152ebae891585d5fbbbb1957f62c68fca3b342b8ca986d53611677aff4566ad4483afb3c69f40738be4cf5d653ca469e72b5661a SHA512 50330a34d9b7b33c67be079eb871e6dafe29c72f2fc42fec0e51aa9a2e0c1eb95e6d27a4dc1affe6647cdf4c9357545336d48c9e27a7e0106d57532a0f53cdcc

diff --git a/app-misc/pax-utils/pax-utils-1.3.2.ebuild b/app-misc/pax-utils/pax-utils-1.3.2.ebuild
new file mode 100644
index 00000000000..b6580c25265
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.3.2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit python-single-r1 toolchain-funcs
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz
+	https://dev.gentoo.org/~vapier/dist/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="caps debug kernel_linux python seccomp"
+
+RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pyelftools[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+# >=linux-headers-5.8 to pick linux headers with faccessat2, bug #768624
+DEPEND="
+	${RDEPEND}
+	kernel_linux? ( !prefix-guest? ( >=sys-kernel/linux-headers-5.8 ) )
+"
+BDEPEND="
+	caps? ( virtual/pkgconfig )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+_emake() {
+	emake \
+		USE_CAP=$(usex caps) \
+		USE_DEBUG=$(usex debug) \
+		USE_PYTHON=$(usex python) \
+		USE_SECCOMP=$(usex seccomp) \
+		"$@"
+}
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	# Avoid slow configure+gnulib+make if on an up-to-date Linux system
+	if use prefix || ! use kernel_linux; then
+		econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
+	else
+		tc-export CC PKG_CONFIG
+	fi
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake check
+}
+
+src_install() {
+	_emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+
+	use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}