[gentoo-commits] repo/gentoo:master commit in: dev-vcs/tig/

["Georgy Yakovlev" <gyakovlev@gentoo.org>]

commit:     f1c78501029dd7b977e43e76b85a038ebdf03a6b
Author:     Stefan Strogin <steils <AT> gentoo <DOT> org>
AuthorDate: Fri Jun  4 04:09:04 2021 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Fri Jun  4 05:04:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1c78501

dev-vcs/tig: do not install tig-completion.zsh

tig-completion.zsh (installed as /usr/share/zsh/site-functions/_tig)
doesn't work and interferes with '_git' from app-shell/zsh, which
already adds comletion for tig.
Don't install the file to make completion for tig in zsh work.

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Stefan Strogin <steils <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/21116
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 dev-vcs/tig/tig-2.5.3-r1.ebuild | 62 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/dev-vcs/tig/tig-2.5.3-r1.ebuild b/dev-vcs/tig/tig-2.5.3-r1.ebuild
new file mode 100644
index 00000000000..9164067a481
--- /dev/null
+++ b/dev-vcs/tig/tig-2.5.3-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/jonas/tig.git"
+	inherit git-r3 autotools
+else
+	SRC_URI="https://github.com/jonas/tig/releases/download/${P}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+DESCRIPTION="text mode interface for git"
+HOMEPAGE="https://jonas.github.io/tig/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test unicode"
+REQUIRED_USE="test? ( unicode )"
+
+DEPEND="
+	sys-libs/ncurses:0=[unicode?]
+	sys-libs/readline:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-vcs/git
+"
+[[ ${PV} == "9999" ]] && BDEPEND+=" app-text/asciidoc app-text/xmlto"
+
+# encoding/env issues
+RESTRICT="test"
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	econf $(use_with unicode ncursesw)
+}
+
+src_compile() {
+	emake V=1
+	[[ ${PV} == "9999" ]] && emake V=1 doc-man doc-html
+}
+
+src_test() {
+	# workaround parallel test failures
+	emake -j1 test
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-doc-man
+	dodoc doc/manual.html README.html NEWS.html
+	newbashcomp contrib/tig-completion.bash ${PN}
+
+	dodoc contrib/*.tigrc
+}