[gentoo-commits] repo/gentoo:master commit in: sci-electronics/klayout/

["Andreas K. Hüttel" <dilfridge@gentoo.org>]

commit:     54d3c67c6d918e0fa0d87374e9c7509491bedbd5
Author:     Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Sat May 29 13:25:42 2021 +0000
Commit:     Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Sat May 29 13:26:59 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54d3c67c

sci-electronics/klayout: Version bump

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Andreas K. Hüttel <dilfridge <AT> gentoo.org>

 sci-electronics/klayout/Manifest            |  1 +
 sci-electronics/klayout/klayout-0.27.ebuild | 91 +++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/sci-electronics/klayout/Manifest b/sci-electronics/klayout/Manifest
index 9713b62ebfa..f036a31c0bc 100644
--- a/sci-electronics/klayout/Manifest
+++ b/sci-electronics/klayout/Manifest
@@ -1,2 +1,3 @@
 DIST klayout-0.26.11.tar.gz 54455860 BLAKE2B f2e988ef1a68a0d8e612199d1a930a55c9175bebb8ca4cbbedef425d6367ddd3e56999502e0fb4c38043e2f7bf2c75c3acb18c498124c5850379bbfe283cb218 SHA512 c868830494a7181bbc68f543930aaf87a189b5063d212191305a3d2e119921175ff66aa2f87f9a89e8e9e5d8bf2c47ed32b5cd1fb43b85619ee35d8a3ddc063b
 DIST klayout-0.26.9.tar.gz 54223809 BLAKE2B 3800b0f49a77a73d4310485ba8539698b72c4a8f953723f4caee43a8c189aa044f7c8e617bc67640071e81d94e9edadbba11114b6d6edd4fcd67d02df33ec7d9 SHA512 1a163a055806fb9555aaf6253cb63d6ebe9648f6e165dfd1cbaa6d199652fa98363f6ddae32843cde5f768a8c2f42c8b06fb4691ed64e40979a22a96bd73874b
+DIST klayout-0.27.tar.gz 56917189 BLAKE2B 41a66939d6d7a058f9dc1772ba152ff1c311b146f7e2b37da52447cbd7eacc35a26a5fec1516384619ab0680a145f82a120ee7ee2739a5c8e9648836afa07d13 SHA512 475e2d905bc75a13c924f6cd1d08b566ecde92a28ed6a32b1995452e0446d4c75f7856ce3af4430a3b39a3876a3817923a51f3675c5afb33f4ec749acf15e0b4

diff --git a/sci-electronics/klayout/klayout-0.27.ebuild b/sci-electronics/klayout/klayout-0.27.ebuild
new file mode 100644
index 00000000000..046760b5f1c
--- /dev/null
+++ b/sci-electronics/klayout/klayout-0.27.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+RUBY_OPTIONAL=no
+USE_RUBY="ruby26"
+# note: define maximally ONE implementation here
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit toolchain-funcs python-single-r1 ruby-ng
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/klayoutmatthias/${PN}.git"
+	inherit git-r3
+	EGIT_CHECKOUT_DIR=${WORKDIR}/all/${P}
+else
+	SRC_URI="https://www.klayout.org/downloads/source/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Viewer and editor for GDS and OASIS integrated circuit layouts"
+HOMEPAGE="https://www.klayout.de/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	sys-libs/zlib
+	${PYTHON_DEPS}
+	$(ruby_implementations_depend)
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ruby-ng_pkg_setup
+}
+
+each_ruby_configure() {
+	tc-export CC CXX AR LD RANLIB
+	export CFLAGS CXXFLAGS
+	./build.sh \
+		-expert \
+		-dry-run \
+		-qmake "/usr/$(get_libdir)/qt5/bin/qmake" \
+		-ruby "${RUBY}" \
+		-python "${PYTHON}" \
+		-build . \
+		-bin "${T}/bin" \
+		-rpath "/usr/$(get_libdir)/klayout" \
+		-option "${MAKEOPTS}" \
+		-with-qtbinding \
+		-without-64bit-coord \
+		-qt5 || die "Configuration failed"
+}
+
+each_ruby_compile() {
+	emake all
+}
+
+each_ruby_install() {
+	emake install
+
+	cd "${T}/bin" || die
+
+	dodir "/usr/$(get_libdir)/klayout"
+	mv lib* lay_plugins db_plugins "${ED}/usr/$(get_libdir)/klayout/" || die
+
+	mkdir -p "${D}/$(python_get_sitedir)" || die
+	mv pymod/* "${D}/$(python_get_sitedir)/" || die
+	rmdir pymod || die
+
+	dobin *
+
+	python_optimize
+}