[gentoo-commits] repo/gentoo:master commit in: dev-python/pyglet/

["Michał Górny" <mgorny@gentoo.org>]

commit:     444f48f07e5d28191619468a8a15334d7fc06f8f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May 21 07:03:43 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May 21 07:57:22 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=444f48f0

dev-python/pyglet: Bump to 1.5.17

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyglet/Manifest             |  1 +
 dev-python/pyglet/pyglet-1.5.17.ebuild | 62 ++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-python/pyglet/Manifest b/dev-python/pyglet/Manifest
index 243d2c7d653..f0d30ff480b 100644
--- a/dev-python/pyglet/Manifest
+++ b/dev-python/pyglet/Manifest
@@ -1,2 +1,3 @@
 DIST pyglet-1.5.15.tar.gz 6429039 BLAKE2B 5835d2c8c0c6e309664bea4a4001d0b68622379ae27555b640ed4441cb4319bf4ffd2b491cf789cba5639b9ca43e047f1e2cf820e540123939dd386a4c88fbf3 SHA512 0ea6f936895b0f17d7272866ecec7721ae1fb353af3654c49bb09eb81729f939df07ba3cdaf8b8bece345a8f144d56a45dc23d82e1887db306fd08c7989c688e
 DIST pyglet-1.5.16.tar.gz 6446875 BLAKE2B bdc40303b096a91924eb1b9c541cea199792ebf36d857f0466df4c5dff4ec2945dbc6e6c4933a293ae5bd5033dbcf49af913f3b0915082f33ea98a7d5f66fde6 SHA512 5cd1c604245c45f4b9d56c6a6290d301f8a925a4988d847df978b0f4431afb46046592f25d73b54cdf99402022a616afb3eb9c579d5ac29160408a74769f7a43
+DIST pyglet-1.5.17.tar.gz 6448500 BLAKE2B c2e27d5525c1e8eb5203b935b6a901283521ed12cf08b1d18297bd2772b83ee4fd721a9aac4fc41b6249b140b36e70d060d3649f4d2eb30f1e6f1f8fd42aa314 SHA512 3bb9594c02894fc58937b9312187b7848843d591fadb8e46553602ebad7c4b2bfd5dc615cc5f5d0cc1f8b59f10afda8e5130a0dee3c2066decb7af3faf114dae

diff --git a/dev-python/pyglet/pyglet-1.5.17.ebuild b/dev-python/pyglet/pyglet-1.5.17.ebuild
new file mode 100644
index 00000000000..7893369764f
--- /dev/null
+++ b/dev-python/pyglet/pyglet-1.5.17.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Cross-platform windowing and multimedia library for Python"
+HOMEPAGE="http://pyglet.org/"
+SRC_URI="https://github.com/pyglet/pyglet/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples image +sound"
+
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/gst-python[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	image? ( || (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		x11-libs/gtk+:2
+	) )
+	sound? ( || (
+		media-libs/openal
+		media-sound/pulseaudio
+	) )
+"
+#	ffmpeg? ( media-libs/avbin-bin )
+
+DOCS=( DESIGN NOTICE README.md RELEASE_NOTES )
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	xdg_environment_reset
+
+	# Specify path to avoid running interactive tests
+	# We could add in integration tests, but they're slow
+	epytest tests/unit
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}