[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-shell-extension-control-blur-effect-on-lock-screen/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     6ec58a51dd5ee5197c4f5bdb4c3d767c545cb56d
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu May 20 12:18:28 2021 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu May 20 12:37:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ec58a51

gnome-extra/gnome-shell-extension-control-blur-effect-on-lock-screen: Support newer gnome versions

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 ...l-blur-effect-on-lock-screen-20201211-r1.ebuild | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/gnome-extra/gnome-shell-extension-control-blur-effect-on-lock-screen/gnome-shell-extension-control-blur-effect-on-lock-screen-20201211-r1.ebuild b/gnome-extra/gnome-shell-extension-control-blur-effect-on-lock-screen/gnome-shell-extension-control-blur-effect-on-lock-screen-20201211-r1.ebuild
new file mode 100644
index 00000000000..2f485afe467
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-control-blur-effect-on-lock-screen/gnome-shell-extension-control-blur-effect-on-lock-screen-20201211-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils
+
+DESCRIPTION="Control the blur effect on gnome-shell lock screen"
+HOMEPAGE="https://github.com/PRATAP-KUMAR/Control_Blur_Effect_On_Lock_Screen"
+COMMIT="748b95e931b6b1548b90ceeee7a5883da3e0529f"
+SRC_URI="https://github.com/PRATAP-KUMAR/Control_Blur_Effect_On_Lock_Screen/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# glib for glib-compile-schemas at build time, needed at runtime anyways
+COMMON_DEPEND="
+	dev-libs/glib:2
+"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-3.36.4
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND=""
+
+S="${WORKDIR}/Control_Blur_Effect_On_Lock_Screen-${COMMIT}"
+extension_uuid="ControlBlurEffectOnLockScreen@pratap.fastmail.fm"
+
+PATCHES=(
+	# https://github.com/PRATAP-KUMAR/Control_Blur_Effect_On_Lock_Screen/issues/3
+	"${FILESDIR}/${P}-metadata.patch"
+)
+
+src_compile() { :; }
+
+src_install() {
+	einstalldocs
+	insinto /usr/share/glib-2.0/schemas
+	doins schemas/*.xml
+	rm -rf LICENSE README.md schemas
+	insinto /usr/share/gnome-shell/extensions/"${extension_uuid}"
+	doins -r *
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}