[gentoo-commits] repo/gentoo:master commit in: x11-apps/igt-gpu-tools/

["Thomas Deutschmann" <whissi@gentoo.org>]

commit:     432b53e72783e865cb3349568a445ffbb5aab3e7
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Sun May 16 21:43:18 2021 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Sun May 16 21:48:27 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=432b53e7

x11-apps/igt-gpu-tools: bump to v1.26

Closes: https://bugs.gentoo.org/789618
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 x11-apps/igt-gpu-tools/Manifest                  |   1 +
 x11-apps/igt-gpu-tools/igt-gpu-tools-1.26.ebuild | 106 +++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/x11-apps/igt-gpu-tools/Manifest b/x11-apps/igt-gpu-tools/Manifest
index cdfc2905b99..50928725b1e 100644
--- a/x11-apps/igt-gpu-tools/Manifest
+++ b/x11-apps/igt-gpu-tools/Manifest
@@ -1 +1,2 @@
 DIST igt-gpu-tools-1.25.tar.xz 1425652 BLAKE2B 1dd17e8542c126d356478acd07344d8732013a24fd180064d6f2277be76170924e7031fd2529b2aa054b40d5093d9cd95271e156bc6b97a75158c84de142f1ba SHA512 a24ee46092241da26fc2dac2b9b54c9f16f7a408c8740c9c7209e876929e2908a36261ba258ca4a4a4e4a21c1e9c919457bf98d514f81d8b7dbfcf5f89a74daf
+DIST igt-gpu-tools-1.26.tar.xz 1573468 BLAKE2B 31fa9cd61fd9a120c72e78cb5ecbc686477ae82572c702bdd6bbc11ba49dc052b7cf52fa486b93e51c87389d73f892577c1d22ebe71d6f50b1565f32355021d1 SHA512 6eb67f68da1c79fac61e5abd57433ef51dbeb2b6f0923dc84aefb81d7059fbc94378fadcd7321a8f059edd9bac640032bf53c3aa058cf570fe5c31924396af8f

diff --git a/x11-apps/igt-gpu-tools/igt-gpu-tools-1.26.ebuild b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.26.ebuild
new file mode 100644
index 00000000000..ff456add5f0
--- /dev/null
+++ b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.26.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+EGIT_REPO_URI="https://gitlab.freedesktop.org/drm/${PN}.git"
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python3_{7..10} )
+inherit ${GIT_ECLASS} meson python-any-r1
+
+DESCRIPTION="Intel GPU userland tools"
+
+HOMEPAGE="https://01.org/linuxgraphics https://gitlab.freedesktop.org/drm/igt-gpu-tools"
+if [[ ${PV} = *9999* ]]; then
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.x.org/releases/individual/app/${P}.tar.xz"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="chamelium doc man overlay runner tests unwind valgrind video_cards_amdgpu video_cards_intel video_cards_nouveau X xv"
+REQUIRED_USE="
+	|| ( video_cards_amdgpu video_cards_intel video_cards_nouveau )
+	overlay? (
+		video_cards_intel
+		|| ( X xv )
+	)
+	doc? ( tests )
+"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/elfutils
+	dev-libs/glib:2
+	sys-apps/kmod:=
+	sys-libs/libunwind:=
+	sys-libs/zlib:=
+	sys-process/procps:=
+	virtual/libudev:=
+	>=x11-libs/cairo-1.12.0[X?]
+	>=x11-libs/libdrm-2.4.82[video_cards_amdgpu?,video_cards_intel?,video_cards_nouveau?]
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/pixman
+	chamelium? (
+		dev-libs/xmlrpc-c[curl]
+		sci-libs/gsl
+		media-libs/alsa-lib:=
+	)
+	overlay? (
+		>=x11-libs/libXrandr-1.3
+		xv? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXv
+		)
+	)
+	runner? ( dev-libs/json-c:= )
+	unwind? ( sys-libs/libunwind )
+	valgrind? ( dev-util/valgrind )
+	"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-util/gtk-doc-1.25-r1 )
+	man? ( dev-python/docutils )
+	overlay? (
+		>=dev-util/peg-0.1.18
+		x11-base/xorg-proto
+	)
+	video_cards_intel? (
+		sys-devel/bison
+		sys-devel/flex
+	)
+"
+BDEPEND="${PYTHON_DEPS}"
+
+src_prepare() {
+	sed -e "s/find_program('rst2man-3'/find_program('rst2man.py', 'rst2man-3'/" -i man/meson.build
+	default_src_prepare
+}
+
+src_configure() {
+	local gpus=""
+	use video_cards_amdgpu  && gpus+="amdgpu,"
+	use video_cards_intel   && gpus+="intel,"
+	use video_cards_nouveau && gpus+="nouveau,"
+
+	local overlay_backends=""
+	use overlay && use xv && overlay_backends+="xv,"
+	use overlay && use X && overlay_backends+="x,"
+
+	local emesonargs=(
+		$(meson_feature chamelium)
+		$(meson_feature doc docs)
+		$(meson_feature man)
+		$(meson_feature overlay)
+		$(meson_feature runner)
+		$(meson_feature tests)
+		$(meson_feature valgrind)
+		$(meson_feature unwind libunwind)
+		-Doverlay_backends=${overlay_backends%?}
+		-Dlibdrm_drivers=${gpus%?}
+	)
+	meson_src_configure
+}