[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     945d53cc7153f0ed9a728a6e6510f22b683d4951
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat May 15 17:54:26 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat May 15 17:55:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=945d53cc

sys-kernel/gentoo-kernel-bin: bump to 5.11.21 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.11.21-r1.ebuild            | 115 +++++++++++++++++++++
 2 files changed, 116 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 7760d0f6767..76172c473b9 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -39,6 +39,7 @@ DIST gentoo-kernel-5.11.20-1.amd64.xpak 65858318 BLAKE2B f1df321519818dfb9793d0e
 DIST gentoo-kernel-5.11.20-1.arm64.xpak 59763123 BLAKE2B d58f09c3ba6f128e1d5ededa610f362de5c5e3d83fa5fe90debb483e18f37df7fc560757c74bb35d2a65bb0bd535cef706f8c20a4610cb5402952543b8f221ac SHA512 0f5fccb84b71859f8e1df59f5f2f5c516d4a6efce9cdfddd39314c05bde34b389bc495364842a24f0044e433521cd99e2ecafc3b12529aa2231fbd04e79bfd87
 DIST gentoo-kernel-5.11.20-1.x86.xpak 57648197 BLAKE2B 7fbcdcb48e752fd594287b06d9936535156f6cf4fe5370c5ac7a98c1e6dcf77bc3a78bcfce5baa101a47eae65fc58aff3a725644570fd816e9d2c56a74cd4f86 SHA512 ed2c69a0d395fe7f53018e4ffb4ad66cc08b9908b48f5d17f7fc18a5752f0f7264eb8355610fd0f23803191233fdd28d5bfe4e7eb24f5d1ebc56f8d584a6539c
 DIST gentoo-kernel-5.11.21-1.amd64.xpak 65876585 BLAKE2B c16eb8a5715e5bb06fd558687a9cebf58639346c919b32664d7f03922fe0a250ec3be58a425fabd512a143331d22a3c7c20bde9c86f7bbd94d4b4d2c41b1e0ee SHA512 acaf8f44546ae78ddaf39a7b8d36d220dfcd72d6cf812f62a3cfcff4a803ba7385a915428cc5d5c01d8b92b3fed9020f185f8fc9c3dcab53d28be277f4b09f04
+DIST gentoo-kernel-5.11.21-1.arm64.xpak 59742584 BLAKE2B 030c9dfd403daf52f453cedfe6742932f1118849768564d8e3363a7f02f306c039555708f234069863367d70d9a355ff3532bfb1bce76a5513bfb5a7f3471f59 SHA512 a7afbead23e20d54eb24070dc791077e0d5e6ff58d398bca4b96fd009dec45fce4e324fb6930e5589f1e0b8132b989ff9fca50ce266c840eaff82962456a2849
 DIST gentoo-kernel-5.11.21-1.x86.xpak 57640449 BLAKE2B 7ced7266ea2f1088979c0ba5c9b9a8ea2f72a92469ab805e767261d1845f30e2d498c1b42e762b97487e536f6f92aabc2db33ee5ff9ffd59e311763fac6d503b SHA512 898956702a54bc9314bfd8a8f825dad30d52cd3fa09f70c46a1698fb8203d92fae5c5a426aa91a7ab34647b1f889fa2068a3822925c438f57c4559be1feaaf44
 DIST gentoo-kernel-5.4.115-1.amd64.xpak 61381562 BLAKE2B e36468cb61a73daffd9709bc8e13eb1c11a0ec1e8f68df55c07eaa50e7538337534ca48342b019b308c99c121628f55c868a5577b2c1a5a4a67cdd72a6fea8ef SHA512 5bb1836cfd7b746aa5d8e947d6fe63c368f86a0d439e56106a77b3f3c3999d3761f238bfd76b5785035ff68869da271a2c3a4dfb5f09fb16b343e0d296ad9d60
 DIST gentoo-kernel-5.4.115-1.arm64.xpak 56473345 BLAKE2B ba662f7d08629dc4fd8978de1db9f0f4400cde21802590a168f9737da03013e27c09a5ecbadcc99f482c935f20db61f9395bc006390b46bea45af305f1677620 SHA512 2ee5adf31d0a8c2bfa76cfadd5c56e818cf31cea3323c91517cd752ce4c87256c2a4f33583119977e37538669d5e2046f77fdd0b9c6adf15ccc498e7179a2088

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.21-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.21-r1.ebuild
new file mode 100644
index 00000000000..2760e617c65
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.21-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}