[gentoo-commits] proj/kde:master commit in: kde-apps/kwrite/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     d85e7d6a4cd58b35aacf99ac83b90f2ea67ee71d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed May 12 07:36:05 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed May 12 07:36:05 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=d85e7d6a

kde-apps/kwrite: 21.04.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/kwrite/kwrite-21.04.1.ebuild | 57 +++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/kde-apps/kwrite/kwrite-21.04.1.ebuild b/kde-apps/kwrite/kwrite-21.04.1.ebuild
new file mode 100644
index 0000000000..8361fce42e
--- /dev/null
+++ b/kde-apps/kwrite/kwrite-21.04.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_ORG_NAME="kate"
+ECM_HANDBOOK="optional"
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Simple text editor based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/en/kwrite"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="activities"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# delete colliding kate translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "kwrite*" -delete || die
+		rm -rf po/*/docs/kate* || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		-DBUILD_addons=FALSE
+		-DBUILD_kate=FALSE
+	)
+	use handbook && mycmakeargs+=( -DBUILD_katepart=FALSE )
+
+	ecm_src_configure
+}