[gentoo-commits] repo/gentoo:master commit in: sys-fs/cryfs/

["Sam James" <sam@gentoo.org>]

commit:     df47ec0c68cf4108f869e285009f6e304ec41551
Author:     Matthew Bakhtiari <dev <AT> mtbk <DOT> me>
AuthorDate: Sun May  9 09:02:21 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon May 10 09:36:18 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=df47ec0c

sys-fs/cryfs: bump to 0.10.3

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Matthew Bakhtiari <dev <AT> mtbk.me>
Closes: https://github.com/gentoo/gentoo/pull/20733
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-fs/cryfs/Manifest            |  1 +
 sys-fs/cryfs/cryfs-0.10.3.ebuild | 99 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 100 insertions(+)

diff --git a/sys-fs/cryfs/Manifest b/sys-fs/cryfs/Manifest
index bb4b24ade0c..f06ae97762b 100644
--- a/sys-fs/cryfs/Manifest
+++ b/sys-fs/cryfs/Manifest
@@ -1 +1,2 @@
 DIST cryfs-0.10.2.tar.xz 7902252 BLAKE2B 704d124ed32a8a958f400188af99498cedb706ccfc004131b677a113b6ab2733942becb1ab64fd06d0b9d5b39f7abe832b3b0669caaf2b6feb7c6577c8c7fbfd SHA512 e49dd6d1e402d968cc4df0e8ca0460a01a27e4e73482041dca0fa9cde905a91d12e2bda18d257a044335e32e316b9363cecf374eb2ca621924b394dd2fabcb8f
+DIST cryfs-0.10.3.tar.xz 7908228 BLAKE2B e1c816bd2ceb125573f5385c6ddb316a600275f0b907d89d3ab32f2050f1a0874ebbfd3db7b452b41d20dcbdd01bf59210a0a96c5bfee079ce222307d4c55596 SHA512 a1325c79cb253219bb092fd68399d6ec68aaf3d78bc95608582ab0c239dfaa0361416531cd1051661e4699b1e79867547710ea55d23e5697ebd4421c937d5b87

diff --git a/sys-fs/cryfs/cryfs-0.10.3.ebuild b/sys-fs/cryfs/cryfs-0.10.3.ebuild
new file mode 100644
index 00000000000..16a91505cca
--- /dev/null
+++ b/sys-fs/cryfs/cryfs-0.10.3.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit cmake flag-o-matic linux-info python-any-r1
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/cryfs/cryfs"
+else
+	SRC_URI="https://github.com/cryfs/cryfs/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+	S="${WORKDIR}"
+fi
+
+DESCRIPTION="Encrypted FUSE filesystem that conceals metadata"
+HOMEPAGE="https://www.cryfs.org/"
+
+LICENSE="LGPL-3 MIT"
+SLOT="0"
+IUSE="custom-optimization debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/boost-1.65.1:=
+	>=dev-libs/crypto++-8.2.0:=
+	net-misc/curl:=
+	>=sys-fs/fuse-2.8.6:0
+	dev-libs/openssl:0=
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	test? ( dev-cpp/gtest )
+"
+
+PATCHES=(
+	# TODO upstream:
+	"${FILESDIR}/0.10.2-unbundle-libs.patch"
+	"${FILESDIR}/0.10.2-install-targets.patch"
+)
+
+pkg_setup() {
+	local CONFIG_CHECK="~FUSE_FS"
+	local WARNING_FUSE_FS="CONFIG_FUSE_FS is required for cryfs support."
+
+	check_extra_config
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# don't install compressed manpage
+	cmake_comment_add_subdirectory doc
+
+	# remove tests that require internet access to comply with Gentoo policy
+	sed -e "/CurlHttpClientTest.cpp/d" -e "/FakeHttpClientTest.cpp/d" \
+		-i test/cpp-utils/CMakeLists.txt || die
+
+	# /dev/fuse access denied
+	sed -e "/CliTest_IntegrityCheck/d" \
+		-i test/cryfs-cli/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBoost_USE_STATIC_LIBS=OFF
+		-DCRYFS_UPDATE_CHECKS=OFF
+		-DBUILD_SHARED_LIBS=OFF
+		-DUSE_SYSTEM_LIBS=ON
+		-DBUILD_TESTING=$(usex test)
+	)
+	use custom-optimization || append-flags -O3
+	use debug || append-flags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_test() {
+	local TMPDIR="${T}"
+	local tests_failed=()
+
+	# fspp fuse tests hang, bug # 699044
+	for i in gitversion cpp-utils parallelaccessstore blockstore blobstore cryfs cryfs-cli ; do
+		"${BUILD_DIR}"/test/${i}/${i}-test || tests_failed+=( "${i}" )
+	done
+
+	if [[ -n ${tests_failed[@]} ]] ; then
+		eerror "The following tests failed:"
+		eerror "${tests_failed[@]}"
+		die "At least one test failed"
+	fi
+}
+
+src_install() {
+	cmake_src_install
+	doman doc/man/cryfs.1
+}